blob: 8ed866a846c42ec25ef2931e3915e6075421fbc3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
|
# Maintainer: Vitalii Kuzhdin <vitaliikuzhdin@gmail.com>
_basename="zls"
pkgver=0.12.0
_pkgver="${pkgver%.*}"
pkgrel=2
_pkgname="${_basename}${_pkgver}"
pkgname="${_pkgname}-bin"
pkgdesc="A language server for Zig"
arch=(
'aarch64'
# 'armv7h'
'i686'
# 'powerpc64le'
# 'riscv64'
'x86_64'
)
url="https://zigtools.org/zls"
license=('MIT')
depends=(
'sh'
"zig${_pkgver}"
)
makedepends=(
'minisign'
)
provides=(
"${_pkgname}"
)
conflicts=(
"${_pkgname}"
)
source=("${_basename}-versioned.sh")
source_aarch64=("https://builds.zigtools.org/${_basename}-linux-aarch64-${pkgver}.tar.xz"
"https://builds.zigtools.org/${_basename}-linux-aarch64-${pkgver}.tar.xz.minisig")
# source_armv7h=("https://builds.zigtools.org/${_basename}-linux-armv7a-${pkgver}.tar.xz"
# "https://builds.zigtools.org/${_basename}-linux-armv7a-${pkgver}.tar.xz.minisig")
source_i686=("https://builds.zigtools.org/${_basename}-linux-x86-${pkgver}.tar.xz"
"https://builds.zigtools.org/${_basename}-linux-x86-${pkgver}.tar.xz.minisig")
# source_powerpc64le=("https://builds.zigtools.org/${_basename}-linux-powerpc64le-${pkgver}.tar.xz"
# "https://builds.zigtools.org/${_basename}-linux-powerpc64le-${pkgver}.tar.xz.minisig")
# source_riscv64=("https://builds.zigtools.org/${_basename}-linux-riscv64-${pkgver}.tar.xz"
# "https://builds.zigtools.org/${_basename}-linux-riscv64-${pkgver}.tar.xz.minisig")
source_x86_64=("https://builds.zigtools.org/${_basename}-linux-x86_64-${pkgver}.tar.xz"
"https://builds.zigtools.org/${_basename}-linux-x86_64-${pkgver}.tar.xz.minisig")
sha256sums=('b9e70d344290a58c6e8199a22232fbd2a8789cf76ddf0574f0a4ea647299ea68')
sha256sums_aarch64=('ea81ee5c64c8b39aaf23c26d641e263470738d76bee945db9f7207bad10f6d6f'
'SKIP')
sha256sums_i686=('f9ed28d9eb12701b85aafd1956d0d2622086a11761a68561de26677f6410ae6c'
'SKIP')
sha256sums_x86_64=('a1049798c9d3b14760f24de5c0a6b5a176abd404979828342b7319939563dfaa'
'SKIP')
if [ "${CARCH}" = 'aarch64' ]; then _arch=aarch64;
elif [ "${CARCH}" = 'armv7h' ]; then _arch=armv7a;
elif [ "${CARCH}" = 'i686' ]; then _arch=x86;
elif [ "${CARCH}" = 'powerpc64le' ]; then _arch=powerpc64le;
elif [ "${CARCH}" = 'riscv64' ]; then _arch=riscv64;
elif [ "${CARCH}" = 'x86_64' ]; then _arch=x86_64;
else _arch=DUMMY;
fi
verify() {
# https://zigtools.org/zls/releases/0.12.0/
local zls_minisign="RWR+9B91GBZ0zOjh6Lr17+zKf5BoSuFvrx2xSeDE57uIYvnKBGmMjOex"
minisign -V \
-P "${zls_minisign}" \
-m "${_basename}-linux-${_arch}-${pkgver}.tar.xz"
}
prepare() {
cd "${srcdir}"
sed -e "s|@@ZIG_PATH@@|/opt/zig${_pkgver}|g" \
-e "s|@@ZLS_PATH@@|/usr/lib/${_pkgname}|g" \
-i "${_basename}-versioned.sh"
}
package() {
cd "${srcdir}"
install -vDm755 "${_basename}-versioned.sh" "${pkgdir}/usr/bin/${_pkgname}"
install -vDm755 "${_basename}" "${pkgdir}/usr/lib/${_pkgname}/${_basename}"
install -vDm644 "README.md" "${pkgdir}/usr/share/doc/${_pkgname}/README.md"
install -vDm644 "LICENSE" "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSE"
}
|