blob: fe9c63f51cfb9ac093be63e6283d72cd13020b8e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# Maintainer: netcrusher < tobias AT miglix DOT eu >
# Maintainer: Caleb Maclennan <caleb@alerque.com>
# Contributor: Gordian Edenhofer <gordian.edenhofer@gmail.com>
_basename=zoom
pkgname="$_basename-system-qt"
pkgver=5.3.465578.0920
pkgrel=1
pkgdesc="Video Conferencing and Web Conferencing Service - system Qt libraries"
arch=('x86_64')
license=('custom')
url='https://zoom.us/'
provides=('zoom')
conflicts=('zoom')
makedepends=('patchelf')
depends=('ttf-font' 'pulseaudio-alsa'
'qt5-base' 'qt5-graphicaleffects' 'qt5-imageformats' 'qt5-quickcontrols' 'qt5-quickcontrols2'
'qt5-svg' 'qt5-script' 'qt5-declarative')
optdepends=('qt5-webengine: SSO login support'
'picom: extra compositor needed by some window managers for screen sharing'
'xcompmgr: extra compositor needed by some window managers for screen sharing')
options=(!strip)
source=("${pkgname}-${pkgver}_orig_x86_64.pkg.tar.xz"::"https://zoom.us/client/${pkgver}/zoom_x86_64.pkg.tar.xz")
sha512sums=('f38ca4dfa322256d6f6532954689a57834bc85e96fcab6c7bc22e21e63c210536dd0a9a6c71a036ff988525e70191ec373a9825b3c7f8dea31a3c78c41bd6b18')
package() {
cp -dpr --no-preserve=ownership opt usr "${pkgdir}"
cd "${pkgdir}/opt/zoom"
# Fix spurious RPATH in binaries
patchelf --shrink-rpath zoom
patchelf --shrink-rpath zopen
rm -f qtdiag
# Remove Qt libraries
rm -f libQt5*.so{,.*}
rm -f libicu*.so{,.*}
rm -rf {egldevice,xcbgl}integrations
rm -rf audio
rm -rf generic
rm -rf iconengines
rm -rf imageformats
rm -rf platforms
rm -rf platforminputcontexts
rm -rf platformthemes
rm -rf Qt{,GraphicalEffects,Qml,Quick,Quick.2}
rm -f libmpg123.so
rm -f libfaac1.so
rm -f libturbojpeg.so{,.*}
rm -f libquazip.so{,.*}
rm qt.conf
# Remove unnecessary executable flag
chmod -x *.pcm
chmod -x *.pem
chmod -x sip/*.{wav,WAV}
}
|