blob: 817467972507ddc7f6d906ebe886ac1140282fd2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer: éclairevoyant
# Contributor: Sefa Eyeoglu <contact at scrumplex dot net>
# Contributor: Alexandros Theodotou <alex at zrythm dot org>
pkgname=zrythm
_pkgver=1.0.0-beta.4.12.1
pkgver="${_pkgver/-/.}"
pkgrel=1
pkgdesc='Highly automated and intuitive digital audio workstation'
arch=(x86_64 i686)
url="https://www.zrythm.org"
license=(AGPL3)
depends=(qt5-base gtk4 libadwaita libpanel gtksourceview5 graphviz carla-git fluidsynth vamp-plugin-sdk guile libaudec xxhash libcyaml reproc libbacktrace rubberband fftw sratom serd portaudio breeze-icons rtmidi rtaudio lsp-dsp-lib sdl2 chromaprint boost dconf libxrandr graphene libepoxy json-glib libxinerama lilv)
makedepends=(git meson cmake ruby-sass help2man sassc)
optdepends=('realtime-privileges: allow memory locking')
options=('debug')
source=("https://www.zrythm.org/releases/$pkgname-$_pkgver.tar.xz"{,.asc}
"git+https://github.com/drobilla/zix.git"
0001-gcc13-fixes.patch)
sha256sums=('60a4b64be3b7103ce06e6cccadfbe706254ad77fa8ee76588e4590674941301b'
'SKIP'
'SKIP'
'bb93eea519020e491f85c38ab3901ac530bbf747c4e7acc3aaea39f402091653')
validpgpkeys=('48132384AD3DF7D86E254B83022EAE42313D70F3') # Alexandros Theodotou <alex@zrythm.org>
prepare() {
cd $pkgname-$_pkgver
patch -Np1 -i ../0001-gcc13-fixes.patch
# use our local clones
sed -i "s|https://github.com/drobilla/zix|$srcdir/zix|" "subprojects/zix.wrap"
meson subprojects download zix
}
build() {
cd $pkgname-$_pkgver
meson build --prefix=/usr \
--wrap-mode nofallback \
--force-fallback-for=zix-0 \
-Ddebug=true \
-Dmanpage=true \
-Dcheck_updates=false \
-Dcarla_binaries_dir=/usr/lib/carla \
-Dportaudio=enabled -Drtmidi=enabled -Drtaudio=enabled -Dsdl=enabled
ninja -C build
}
package() {
cd $pkgname-$_pkgver
install -vDm644 AUTHORS CONTRIBUTING.md \
CHANGELOG.md README.md THANKS TRANSLATORS \
-t "$pkgdir/usr/share/doc/$pkgname/"
meson install -C build --destdir="$pkgdir"
}
|