blob: 483e81397fff30483fef2a6db10fb3e88fc9e868 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Maintainer: Alexandros Theodotou <alex at zrythm dot org>
pkgname=zrythm
pkgver=0.6.422
pkgrel=1
pkgdesc='a highly automated and intuitive digital audio workstation'
arch=('x86_64' 'i686')
url="https://www.zrythm.org"
license=('AGPL3')
depends=('gtk3' 'lilv' 'libx11' 'jack' 'libsndfile'
'libyaml' 'libsamplerate' 'alsa-lib' 'fftw')
makedepends=(
'python' 'gettext' 'sed'
'meson' 'ninja' 'help2man' 'python-sphinx'
'ladspa' 'lv2' 'suil')
optdepends=('portaudio: portaudio backend'
'qt5-base: for embedding qt5 plugin UIs')
conflicts=('zrythm-git')
source=("https://download.savannah.nongnu.org/releases/$pkgname/$pkgname-$pkgver.tar.xz"{,.asc})
#source=("https://download-mirror.savannah.nongnu.org/releases/$pkgname/$pkgname-$pkgver.tar.xz"{,.asc})
sha256sums=('57688679b7bb8a5e501386d9986a707f1b751ef7d70f68085e82b225fc02d400'
'SKIP')
validpgpkeys=('48132384AD3DF7D86E254B83022EAE42313D70F3')
build() {
cd "$pkgname-$pkgver"
meson build --buildtype=release --prefix=/usr -Denable_tests=true -Duser_manual=true -Dmanpage=true
ninja -C build
}
check() {
cd "$pkgname-$pkgver"
ninja -C build test
}
package() {
cd "$pkgname-$pkgver"
install -vDm 644 AUTHORS CONTRIBUTING.md CHANGELOG.md README.md THANKS TRANSLATORS \
-t "${pkgdir}/usr/share/doc/${pkgname}/"
DESTDIR="${pkgdir}/" ninja -C build install
}
|