blob: 54be4a358b3413cc1dff6b0179105f1d080f4d4f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Maintainer: Alexandros Theodotou <alex at alextee dot org>
_pkgname=zrythm
pkgname=$_pkgname-git
pkgver=r161.f6a97a6
pkgrel=1
pkgdesc="Free GNU/Linux music production system (DAW)"
arch=('x86_64')
url="https://gitlab.com/alextee/zrythm"
license=('GPL3')
provides=("$_pkgname")
conflicts=("$_pkgname")
depends=('gtk3' 'lv2' 'lilv' 'suil' 'jack' 'libsndfile' 'libsmf' 'libdazzle')
makedepends=('git')
source=("$_pkgname::git+https://gitlab.com/alextee/zrythm.git"
"git+https://github.com/KDE/breeze-icons.git")
md5sums=('SKIP'
'SKIP')
pkgver () {
cd "$srcdir/$_pkgname"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
cd "$srcdir/$_pkgname"
git submodule init
git config submodule."ext/breeze-icons".url "$srcdir/breeze-icons"
git submodule update
}
build() {
cd "$srcdir/$_pkgname"
autoreconf -fi
./configure --prefix=/usr --enable-aur-build
make
}
package() {
cd "$srcdir/$_pkgname"
make DESTDIR="$pkgdir" install
}
|