PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48

# Maintainer: Sebastian wniazdowski <psprint at zdharma dot org>

_name='zsh-zplugin-git'
pkgname="${_name}"
pkgver=r1479.bb02e20
pkgrel=1
pkgdesc="Flexible Zsh plugin manager with clean fpath, reports, completion management, turbo mode"
url="http://github.com/zdharma/zplugin"
arch=('any')
license=('GPL' 'MIT')
depends=('zsh>=4.3.17')
provides=('zsh-zplugin')
conflicts=('zsh-zplugin')
makedepends=('git')
source=('git+https://github.com/zdharma/zplugin.git')
sha512sums=('SKIP')

_gitname='zplugin'

pkgver() {
    cd "${_gitname}"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

package() {
    # .../zplugin
    typeset _plugindir="${pkgdir}/usr/share/zsh/plugin-managers/${_gitname}"
    typeset _bindir="${_plugindir}"
    # .../zsh-zplugin-git
    typeset _licdir="${pkgdir}/usr/share/licenses/${pkgname}" 

    cd "${srcdir}/${_gitname}"

    # Zplugin's source files
    install -dm0755 "${_plugindir}"
    install -m0644 zplugin{,-side,-install,-autoload}.zsh "${_plugindir}"
    install -m0755 git-process-output.zsh "${_plugindir}"
    install -m0744 _zplugin "${_plugindir}"

    # Zplugin-module files
    find zmodules/ -type d -exec install -dm 755 "{}" "${_plugindir}/{}" \;
    find zmodules/ -type f -exec install -m 744 "{}" "${_plugindir}/{}" \;

    # Installation script, ad-hoc tests, etc.
    cd ${srcdir}/${_gitname}"/doc"
    install -dm0755 "${_plugindir}/doc"
    install -m0644 -- *install.sh test-* zcompile zplugin.1 "${_plugindir}/doc"
}