blob: b82a090811dc91aee4448d3a907f40e8c8fee06b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
|
# Maintainer: Sam Guymer <sam at guymer dot me>
_jdkname=zulu-12
pkgname="${_jdkname}-bin"
_java_ver=12
_zulu_build=12.2.3-ca
pkgver=12.0.1
pkgrel=1
pkgdesc='Zulu is a certified build of OpenJDK that is fully compliant with the Java SE standard.'
arch=('x86_64')
url='https://www.azul.com/zulu'
license=('custom')
depends=(
# not 100% sure if all of these dependencies are needed
# dependencies from jre11-openjdk-headless
'java-runtime-common>=3' 'ca-certificates-utils' 'nss' 'libjpeg-turbo' 'lcms2' 'libnet' 'freetype2'
# dependencies from jre11-openjdk
'giflib'
# dependencies from java11-openjdk
'java-environment-common=3' 'hicolor-icon-theme' 'libelf'
)
provides=(
"java-environment=$_java_ver"
"java-environment-openjdk=$_java_ver"
)
install="$pkgname.install"
_tarballname="zulu${_zulu_build}-jdk${pkgver}-linux_x64"
source=("http://cdn.azul.com/zulu/bin/${_tarballname}.tar.gz")
md5sums=('772a8d0b5f2e610d9061ed448c9221a8')
_jvmdir="/usr/lib/jvm/${_jdkname}"
package() {
cd "$srcdir/${_tarballname}"
install -dm 755 "${pkgdir}/${_jvmdir}"
cp -a . "${pkgdir}/${_jvmdir}/"
# copied from java11-openjdk
# Conf
install -dm 755 "${pkgdir}/etc"
cp -r conf "${pkgdir}/etc/${_jdkname}"
rm -rf "${pkgdir}/${_jvmdir}/conf"
ln -s "/etc/${_jdkname}" "${pkgdir}/${_jvmdir}/conf"
# Legal
install -dm 755 "${pkgdir}/usr/share/licenses"
cp -r legal "${pkgdir}/usr/share/licenses/${_jdkname}"
rm -rf "${pkgdir}/${_jvmdir}/legal"
ln -s "/usr/share/licenses/${_jdkname}" "${pkgdir}/${_jvmdir}/legal"
# Man pages
for f in man/man1/*; do
install -Dm 644 "${f}" "${pkgdir}/usr/share/${f/\.1/-zulu-12.1}"
done
rm -rf "${pkgdir}/${_jvmdir}/man"
ln -s /usr/share/man "${pkgdir}/${_jvmdir}/man"
# Link JKS keystore from ca-certificates-utils
rm -f "${pkgdir}/${_jvmdir}/lib/security/cacerts"
ln -sf /etc/ssl/certs/java/cacerts "${pkgdir}/${_jvmdir}/lib/security/cacerts"
}
|