PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42

# Maintainer: Alexandre Bouvier <contact@amb.tf>
_pkgname=zydis
pkgname=$_pkgname-git
pkgver=4.0.0.r52.g03fd6d8
pkgrel=1
pkgdesc="Fast and lightweight x86/x86-64 disassembler library"
arch=('x86_64')
url="https://zydis.re/"
license=('MIT')
depends=('glibc')
makedepends=('cmake' 'doxygen' 'git' 'ruby-ronn-ng' 'zycore-c>=1.5')
checkdepends=('python')
provides=("$_pkgname=$pkgver" 'libZydis.so')
conflicts=("$_pkgname")
source=("$_pkgname::git+https://github.com/zyantific/zydis.git")
b2sums=('SKIP')

pkgver() {
	cd $_pkgname
	git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
	cmake -S $_pkgname -B build \
		-DCMAKE_BUILD_TYPE=Release \
		-DCMAKE_C_FLAGS_RELEASE="-DNDEBUG" \
		-DCMAKE_INSTALL_PREFIX=/usr \
		-DZYAN_SYSTEM_ZYCORE=ON \
		-DZYDIS_BUILD_EXAMPLES=OFF \
		-DZYDIS_BUILD_MAN=ON \
		-DZYDIS_BUILD_SHARED_LIB=ON \
		-DZYDIS_BUILD_TESTS="$CHECKFUNC" \
		-Wno-dev
	cmake --build build
}

package() {
	depends+=('libZycore.so')
	# shellcheck disable=SC2154
	DESTDIR="$pkgdir" cmake --install build
	install -Dm644 -t "$pkgdir"/usr/share/licenses/$pkgname $_pkgname/LICENSE
}