PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77

# Maintainer: Llewelyn Trahaearn <WoefulDerelict at GMail dot com>
# Contributor: speps <speps at aur dot archlinux dot org>

pkgname=zynaddsubfx-git
pkgver=2.5.3.osx.r1.gb97f65d
pkgrel=1
pkgdesc="A powerful realtime, multi-timbral software synthesizer."
arch=('i686' 'x86_64')
url="http://zynaddsubfx.sourceforge.net"
license=('GPL')
depends=('fftw' 'fltk' 'lash' 'liblo' 'portaudio' 'mxml' 'ntk-git')
makedepends=('git' 'cmake' 'dssi')
optdepends=('dssi: dssi plugin')
provides=("${pkgname%-*}")
conflicts=("${pkgname%-*}")
options=('!emptydirs')
install="${pkgname}.install"
source=("${pkgname}::git://git.code.sf.net/p/zynaddsubfx/code/"
        "http://zynaddsubfx.sourceforge.net/doc/instruments/unsortedzynaddsubfxParameters_20140402.zip")
noextract=("${source[1]##*/}")
sha512sums=('SKIP'
            '13e7ed9746d0ce7959afa067211175cd007fdeb77500756dd5b0a57e6230e425934a7fe267a5197b539c3305c497745beb2fef2f5e79e4c8662a9c57cf2345f0')
_branch=master

pkgver() {
  cd "${srcdir}/${pkgname}"
  git checkout ${_branch} --quiet
  ( set -o pipefail
    git describe --long --tags 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
  )
}
prepare() {
  [ -d build ] || mkdir build
  cd "${srcdir}/${pkgname}"
  git checkout ${_branch}

  # pull rtosc and instruments
  git submodule update --init

  # does not build with --as-needed
  LDFLAGS=${LDFLAGS//,--as-needed}

  # do not use /usr/lib64
  sed -i 's:lib64:lib:' src/CMakeLists.txt
}

build() {
  cd "${srcdir}/build"
  cmake ../"${pkgname}" -DCMAKE_INSTALL_PREFIX=/usr \
           -DCMAKE_INSTALL_LIBDIR=/usr/lib \
           -DGuiModule=ntk
  make

  # External programs
  cd "../${pkgname}/ExternalPrograms/Spliter" && make
  cd "../Controller" && make
}

package() {
  cd "${srcdir}/build"
  make DESTDIR="${pkgdir}/" install

  # External programs and documentation.
  install -Dm755 "../${pkgname}/ExternalPrograms/Spliter/spliter" \
                 "${pkgdir}/usr/bin/spliter"
  install -Dm644 "../${pkgname}/ExternalPrograms/Spliter/readme.txt" \
                 "${pkgdir}/usr/share/doc/zynaddsubfx/SPLITER.txt"
  install -Dm755 "../${pkgname}/ExternalPrograms/Controller/controller" \
                 "${pkgdir}/usr/bin/controller"

  # Additional parameters
  install -d "${pkgdir}/usr/share/zynaddsubfx/parameters"
  bsdtar --strip-components 1 --uid 0 --gid 0 -zxf \
                 ${srcdir}/${source[1]##*/} -C \
                 "${pkgdir}/usr/share/zynaddsubfx/parameters"
}