blob: 68ef065dfa40105f3c6af452eb02b92fe28d99e9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
pkgname=zzuf-git
pkgver=0.14.669.d16576b
pkgrel=1
pkgdesc="Transparent application input fuzzer"
url='https://github.com/samhocevar/zzuf'
arch=('i686' 'x86_64')
license=('custom:WTF')
depends=('glibc')
makedepends=('git')
provides=('zzuf')
conflicts=('zzuf')
source=(${pkgname}::git+https://github.com/samhocevar/zzuf)
sha512sums=('SKIP')
pkgver() {
cd ${pkgname}
printf "%s.%s.%s" "$(git describe --tags --abbrev=0|cut -dv -f2)" \
"$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
cd ${pkgname}
autoreconf -fiv
}
build() {
cd ${pkgname}
./configure --prefix=/usr
make
}
check() {
cd ${pkgname}
# ignore test results because of upstream bug #7
make check||true
}
package() {
cd ${pkgname}
make DESTDIR="${pkgdir}" install
install -Dm 644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
# vim: ts=2 sw=2 et:
|