Arch Linux User Repository

config is found in /etc/anyrun I recommend to cp -r /etc/anyrun/* ~/.config/anyrun/

This package and anyrun-provider-git should be deleted. It has many errors and is not well-constructed. This is how the PKGBUILD should actually be written:

: ${CARGO_HOME:=$SRCDEST/cargo-home}
: ${CARGO_TARGET_DIR:=target}
: ${RUSTUP_TOOLCHAIN:=stable}
export CARGO_HOME CARGO_TARGET_DIR RUSTUP_TOOLCHAIN

pkgname='anyrun-git'
pkgver=r306.d72d303
pkgrel=1
pkgdesc='A wayland native, highly customizable runner'
arch=('x86_64')
url='https://github.com/anyrun-org/anyrun'
license=('GPL-3.0-only')
depends=('gtk4-layer-shell' 'anyrun-provider-git')
makedepends=('git' 'cargo')
provides=('anyrun')
conflicts=('anyrun')
options=('!lto')

source=('anyrun::git+https://github.com/anyrun-org/anyrun.git')
sha256sums=('SKIP')

pkgver() {
  cd anyrun
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  cd anyrun
  cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}

build() {
  cd anyrun
  cargo build --frozen --release --all-features
}

package() {
  cd anyrun

  install -Dm755 "$CARGO_TARGET_DIR/release/anyrun" -t "$pkgdir/usr/bin/"

  for _so in "$CARGO_TARGET_DIR/release"/*.so; do
    [[ "$_so" == *libanyrun_macros* ]] && continue
    install -Dm644 "$_so" -t "$pkgdir/usr/lib/anyrun/"
  done

  install -Dm644 examples/config.ron -t "$pkgdir/etc/xdg/anyrun/"
  sed -i 's|"\(lib[^"]*\.so\)"|"/usr/lib/anyrun/\1"|g' "$pkgdir/etc/xdg/anyrun/config.ron"
  install -Dm644 anyrun/res/style.css -t "$pkgdir/etc/xdg/anyrun/"
}

And this is for the anyrun-provider-git:

: ${CARGO_HOME:=$SRCDEST/cargo-home}
: ${CARGO_TARGET_DIR:=target}
: ${RUSTUP_TOOLCHAIN:=stable}
export CARGO_HOME CARGO_TARGET_DIR RUSTUP_TOOLCHAIN

pkgname='anyrun-provider-git'
pkgver=r14.88a786e
pkgrel=1
pkgdesc='Backend of Anyrun: loads plugins and acts as middleman between launcher and plugins'
arch=('x86_64')
url='https://github.com/anyrun-org/anyrun-provider'
license=('GPL-3.0-only')
makedepends=('git' 'cargo')
provides=('anyrun-provider')
conflicts=('anyrun-provider')
options=('!lto')

source=('anyrun-provider::git+https://github.com/anyrun-org/anyrun-provider.git')
sha256sums=('SKIP')

pkgver() {
  cd anyrun-provider
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  cd anyrun-provider
  cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}

build() {
  cd anyrun-provider
  cargo build --frozen --release --all-features
}

package() {
  cd anyrun-provider

  install -Dm755 "$CARGO_TARGET_DIR/release/anyrun-provider" -t "$pkgdir/usr/bin/"
  install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/anyrun-provider-git/"
}

The license has been added!

this package is broken until anyrun-provider gets a license added to it

I found that this does not build without gtk4-layer-shell.

I found I needed to add the following to the prepare() function:

diff --git a/PKGBUILD b/PKGBUILD
index 1dfde25..f42f46b 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -22,6 +22,8 @@ pkgver() {
 }
 prepare() {
   cd "${srcdir}/${_pkgname}"
+  export RUSTUP_TOOLCHAIN=stable
+  export CARGO_TARGET_DIR=target
   cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
 }
 build() {

....for it to build correctly. Otherwise, it complained that there was no default set.

@AskAlice @markstos This package installs every plugins, don't need to install separate anyrun-plugin-* packages. See PKGBUILD:

cp target/release/*.so "$pkgdir/etc/anyrun/plugins/"

I agree with @AskAlice. This package needs to be considered to "provide" anyrun. Right now if you attempt to install this package now along with a plugin, it fails:

❯ paru -S anyrun-git anyrun-plugin-applications
:: Resolving dependencies...
error: could not find all required packages:
    anyrun (wanted by: anyrun-plugin-applications)

An alternate solution would be for someone to start maintaining the anyrunpackage itself. Right now now package named anyrun is available.

Dear maintainer, i think you need to add a provides on the PKGBUILD so that the the plugins packages which are also on the aur and require anyrun work

provides=(
        "${_pkgname}=$pkgver"
)