Package Details: apkleaks-git v1.0.2.r103.g401e09c-1

Git Clone URL: https://aur.archlinux.org/apkleaks-git.git (read-only, click to copy)
Package Base: apkleaks-git
Description: scanning apk file for URIs, endpoints & secrets. (git version)
Upstream URL: https://github.com/dwisiswant0/apkleaks
Licenses: Apache2
Conflicts: apkleaks
Submitter: theguy147
Maintainer: theguy147
Last Packager: theguy147
Votes: 0
Popularity: 0.000000
First Submitted: 2021-03-25 17:29 (UTC)
Last Updated: 2021-03-25 17:29 (UTC)

Required by (0)

Sources (1)

Latest Comments

xa9e commented on 2025-01-15 23:00 (UTC) (edited on 2025-01-15 23:02 (UTC) by xa9e)

The following PKGBUILD works. I have also tested it in a clean chroot. 

pkgname=apkleaks-git
pkgver=v2.6.3.r0.g05a83a1
pkgrel=1
pkgdesc="Scanning APK files for URIs, endpoints, and secrets (git version)"
url="https://github.com/dwisiswant0/apkleaks"
license=('Apache2')
arch=('any')
depends=('python' 'python-pyaxmlparser' 'python-setuptools')
makedepends=('python-build' 'python-installer' 'python-wheel' 'python-poetry-core' 'git' )
conflicts=('apkleaks')
source=("${pkgname}::git+${url}.git")
sha256sums=('SKIP')

pkgver() {
    cd "${pkgname}"
    ( set -o pipefail
        git describe --long --tags --abbrev=7 | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
        printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
    )
}

build() {
  cd "${srcdir}/${pkgname}"
  python -m build --wheel --no-isolation
}

package() {
  cd "${srcdir}/${pkgname}"
  python -m installer --destdir="${pkgdir}" dist/*.whl
  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}

drygdryg commented on 2024-11-20 07:20 (UTC) (edited on 2024-11-20 07:21 (UTC) by drygdryg)

The build function is broken: the project no longer uses setup.py since it migrated to pyproject.toml. https://github.com/dwisiswant0/apkleaks/commit/1abc5d6c3452bbd37d3dcd11a5dd566b9d65f2f9

==> Starting build()...
python: can't open file '/home/golovanenko.v/.cache/paru/clone/apkleaks-git/src/apkleaks-git/setup.py': [Errno 2] No such file or directory
==> ERROR: A failure occurred in build().
    Aborting...

drygdryg commented on 2024-10-03 07:32 (UTC)

pkgver function is broken. Please use git describe --long --tags --abbrev=7 | sed 's/\([^-]*-g\)/r\1/;s/-/./g', e.g.:

pkgver() {
    cd "${pkgname}"
    ( set -o pipefail
        git describe --long --tags --abbrev=7 | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
        printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
    )
}