Arch Linux User Repository

Regarding the comment by Graith95, the same can be used for armorlab, obviously change the checksums/git repo/edit desktop and sh files.

Also the pkgbuild fails as it looks for "LICENSE.md" when it needs to be "license.md" on line 50.

I have a working PKGBUILD for the 1.0 alpha at https://gist.github.com/GraithTiger/ebab9f777e62b52fe23141622c5669a3

I intend to fix this one as well since I created and took on maintenance of stable (non-git, v0.9 at time of writing).

Right now that's not going to happen though, upstream is completely broken, some of these errors would be trivial to fix but I don't have the time to deep dive the codebase to fix it.

fatal error: too many errors emitted, stopping now [-ferror-limit=] 20 errors generated. make: *** [makefile:12: krom.o] Error 1

It appears the entire project is currently undergoing some kind of restructuring, Kinc/make has been turned to just make, files have moved, etc. I suspect most of these issues will be ironed out in a few weeks when they finish restructuring.

Fixed pkgver build error:

# $Id$
# Maintainer: Julio Campagnolo <juliocampagnolo@gmail.com>

pkgname=('armorpaint-git')
_pkgname='armortools'
pkgver=1.0.alpha.r3637.g15ad4901
pkgrel=1
arch=('i686' 'x86_64')
pkgdesc="ArmorPaint is a software for 3D PBR texture painting"
url="https://armorpaint.org/"
license=('ZLIB')
depends=('mesa' 'alsa-lib' 'libxinerama' 'gcc-libs' 'nodejs')
makedepends=('git' 'nodejs' 'clang' 'make' 'gcc' 'gtk3' 'vulkan-headers')
provides=('armorpaint')
conflicts=('armorpaint')
source=("git+https://github.com/armory3d/armortools"
    "armorpaint.sh"
    "armorpaint.desktop"
    "armorpaint.png")
md5sums=(SKIP
    "74001d6c572fc79c96d0bee24427f7ba"
    "dd5d97aadd39966ff7d9dda68b5ae29a"
    "67cf4a0cb08c66c4a68c677885e8ac99")

pkgver() {
    cd "$srcdir/$_pkgname"
    ver="$(grep -oP 'version = "\K[^"]+' armorpaint/Sources/manifest.ts | sed 's/ /./')"
    printf "%s.r%s.g%s" "$ver" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
    cd "$srcdir/$_pkgname"
    git submodule update --init --recursive
}

build() {
    cd "$srcdir/$_pkgname/armorpaint"
    ../armorcore/Kinc/make --from ../armorcore -g opengl --compiler clang --compile
    cd ../armorcore/Deployment
    strip ArmorPaint
}

package() {
    cd "$srcdir/$_pkgname"
    mkdir -p ${pkgdir}/usr/{bin,share,lib}
    mkdir -p ${pkgdir}/usr/lib/armorpaint
    install -Dm755 ${srcdir}/armorpaint.sh ${pkgdir}/usr/bin/armorpaint
    install -Dm644 LICENSE.md ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
    install -Dm755 armorcore/Deployment/ArmorPaint ${pkgdir}/usr/lib/armorpaint/
    install -Dm644 ${srcdir}/armorpaint.desktop ${pkgdir}/usr/share/applications/armorpaint.desktop
    mkdir -p ${pkgdir}/usr/share/armorpaint
    cp -r build/krom ${pkgdir}/usr/share/armorpaint/krom
    install -Dm644 ${srcdir}/armorpaint.png ${pkgdir}/usr/share/icons/armorpaint.png
}

But unfortunately still unable to build. Some people right now also have troubles, see - https://github.com/armory3d/armortools/issues/1671.

Hi @AmonDeShir, I orphaned the package. Feel free to adopt it.

I fixed build errors:

# $Id$
# Maintainer: Julio Campagnolo <juliocampagnolo@gmail.com>

pkgname=('armorpaint-git')
_pkgname='armortools'
pkgver=1.0.alpha.r3477.g56793906
pkgrel=1
arch=('i686' 'x86_64')
pkgdesc="ArmorPaint is a software for 3D PBR texture painting"
url="https://armorpaint.org/"
license=('ZLIB')
depends=('mesa' 'alsa-lib' 'libxinerama' 'gcc-libs')
makedepends=('git' 'make' 'gcc' 'gtk3' 'vulkan-headers')
provides=('armorpaint')
conflicts=('armorpaint')
source=("git+https://github.com/armory3d/armortools"
        "armorpaint.sh"
        "armorpaint.desktop"
        "armorpaint.png")
md5sums=(SKIP
         "74001d6c572fc79c96d0bee24427f7ba"
         "dd5d97aadd39966ff7d9dda68b5ae29a"
         "67cf4a0cb08c66c4a68c677885e8ac99")

pkgver() {
  cd "${srcdir}/${_pkgname}"
  ver="$(grep -oP 'version = "\K[^"]+' armorpaint/Sources/Manifest.hx | sed 's/ /./')"
  printf "%s.r%s.g%s" "$ver" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
    cd "${srcdir}/${_pkgname}"
    git submodule update --init --recursive
}

build() {
    cd "$srcdir/${_pkgname}/armorpaint"
    ../armorcore/Kinc/make --from ../armorcore -g opengl --compile
    cd ../armorcore/Deployment
    strip ArmorPaint
}

package() {
    cd "$srcdir"/"$_pkgname"
    mkdir -p ${pkgdir}/usr/{bin,share,lib}
    mkdir -p ${pkgdir}/usr/lib/armorpaint
    install -Dm755 ${srcdir}/armorpaint.sh ${pkgdir}/usr/bin/armorpaint
    install -Dm644 LICENSE.md ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
    install -Dm755 armorcore/Deployment/ArmorPaint ${pkgdir}/usr/lib/armorpaint/
    install -Dm644 ${srcdir}/armorpaint.desktop ${pkgdir}/usr/share/applications/armorpaint.desktop
    mkdir -p ${pkgdir}/usr/share/armorpaint
    cp -r armorpaint/build/krom ${pkgdir}/usr/share/armorpaint/krom
    install -Dm644 ${srcdir}/armorpaint.png ${pkgdir}/usr/share/icons/armorpaint.png
}

I changed GitHub URL because main repo was renamed to armortools. I also removed nodejs from dependencies (armorpaint has build-in v8). Furthermore, I had troubles with compilation using clang: "incompatible pointer to integer conversion passing 'zui_node_socket_t ' (aka 'struct zui_node_socket ') to parameter of type 'int' [-Wint-conversion]", in clang14 it was only a warning, but since clang15 it is an error now, unfortunately arch uses clang16. I failed to get kmake to use clang14 instead of the default clang16, so as a workaround, I changed clang to GCC.

The package fails to build.

• Sources/Main.hx has moved to armorpaint/Sources/Main.hx
• build/krom has moved to armorpaint/build/krom

I'm using an Nvidia RTX 2080 and I get incredible gpu usage spike and overheat and a framerate of about 1 frame every 1-3 seconds....it's bad...what am I doing wrong? Should I submit this to the devs?

@Blaster84x package fixed.