Package Details: batorrent-git 4.8.0.beta2.r0.g66a60ff-2

Git Clone URL: https://aur.archlinux.org/batorrent-git.git (read-only, click to copy)
Package Base: batorrent-git
Description: A modern, open-source BitTorrent client focused on privacy, performance, and clarity. No ads, no telemetry.
Upstream URL: https://github.com/Mateuscruz19/BATorrent
Keywords: bittorrent bittorrent-client cpp libtorrent p2p privacy qml qt qt6 rss self-hosted streaming torrent torrent-client torrent-downloader webui
Licenses: MIT
Conflicts: batorrent
Provides: batorrent
Submitter: xotkot
Maintainer: xotkot
Last Packager: xotkot
Votes: 0
Popularity: 0.000000
First Submitted: 2026-06-10 07:00 (UTC)
Last Updated: 2026-07-22 12:10 (UTC)

Latest Comments

ludvick commented on 2026-07-21 15:30 (UTC)

Thank you for the lightning-fast update with qt6-multimedia! Everything compiles and works perfectly now.

Since the application lacks an upstream Linux desktop entry, I prepared an updated PKGBUILD that dynamically generates a .desktop file and installs the official vector logo (logo.svg) from the source to /usr/share/pixmaps/. This allows the app to show up properly in system application menus and launchers.

Feel free to use it if you want to include it in the official AUR package:

# Maintainer: xotkot
pkgname=batorrent-git
pkgver=4.7.0.rc6.r7.g47f808d
pkgrel=1
pkgdesc='A lightweight BitTorrent client built with C++, Qt 6, and libtorrent-rasterbar.'
arch=(x86_64)
url='https://github.com/Mateuscruz19/BATorrent'
license=(MIT)
conflicts=(batorrent)
provides=(batorrent)
depends=(   libtorrent-rasterbar
            qt6-svg
            qt6-declarative
            qt6-multimedia
            qtkeychain-qt6
            qt6-base
            openssl
            libstdc++
            glibc
            libgcc)
makedepends=(git
            cmake
            boost)
source=("$pkgname::git+$url")
b2sums=(SKIP)

pkgver() {
  cd "$pkgname"
  git describe --tags --long --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "$pkgname"
  cmake -B build -DCMAKE_BUILD_TYPE=Release
  cmake --build build -j
}

package() {
  cd "$pkgname"

  # 1. Install the executable binary
  install -Dm0755 "$srcdir/$pkgname/build/BATorrent" "$pkgdir/usr/bin/BATorrent"

  # 2. Install the original vector logo (.svg) from the project repository
  install -Dm0644 "$srcdir/$pkgname/src/images/logo.svg" "$pkgdir/usr/share/pixmaps/BATorrent.svg"

  # 3. Dynamically create and install the .desktop launcher shortcut
  mkdir -p "$pkgdir/usr/share/applications"
  cat <<EOF > "$pkgdir/usr/share/applications/BATorrent.desktop"
[Desktop Entry]
Name=BATorrent
Comment=Lightweight BitTorrent Client
Exec=/usr/bin/BATorrent
Icon=/usr/share/pixmaps/BATorrent.svg
Terminal=false
Type=Application
Categories=Network;FileTransfer;P2P;Qt;
EOF

  # 4. Install the license file
  install -Dm0644 "$srcdir/$pkgname/LICENSE" "$pkgdir/usr/share/licenses/BATorrent/LICENSE"
}

Thanks again for maintaining this package!

ludvick commented on 2026-07-21 06:45 (UTC) (edited on 2026-07-21 06:54 (UTC) by ludvick)

Hi, the build currently fails in a clean chroot environment due to a missing dependency:

-- Could NOT find Qt6Multimedia (missing: Qt6Multimedia_DIR)
CMake Error at CMakeLists.txt:3 (find_package):
  Failed to find required Qt component "Multimedia".

Could you please add 'qt6-multimedia' to the 'depends' array in PKGBUILD? Thanks!