Arch Linux User Repository

@kIERO, thank you so much, applying the change...

Build fails because LICENSE files got moved around.

new licenses are

install -Dm644 $_pkgname/LICENSE "$pkgdir/usr/share/licenses/$_pkgname/LICENSE"
install -Dm644 $_pkgname/LICENSE_STDLIB "$pkgdir/usr/share/licenses/$_pkgname/LICENSE_SRC"

@kIERO Thank you so much for the update. I am testing it in a clean chroot and also a clean archlinux install. If it passes my tests, I will update it :)

I modified the PKGBUILD to be closer to the official c3c package. No curl llvm shenanigans.

Could you perhaps update? Thanks

# Maintainer: Eduardo Jose Gomez Hernandez <eduardo@edujgh.net>
# Contributor: Manuel Barrio Linares <mbarriolinares at gmail dot com>

pkgname=c3c-git
_pkgname=c3c
pkgver=r3282.34bded30
pkgrel=1
pkgdesc='Compiler for the C3 language'
arch=(x86_64)
url='https://github.com/c3lang/c3c'
license=(LGPL-3.0-or-later MIT)
depends=(curl lld llvm-libs)
makedepends=(clang cmake git libedit llvm)
provides=('c3c')
conflicts=('c3c')
source=("git+${url}.git")
b2sums=('SKIP')

pkgver() {
  cd "${srcdir}/${_pkgname}"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  cd $_pkgname
  # Pretend that git is missing and define the git hash manually
  sed -i '/find_package(Git /d' CMakeLists.txt git_hash.cmake
  sed -i "s/unknown/$(git rev-parse HEAD)/g" git_hash.cmake
}

build() {
  cmake \
    -B build \
    -D C3_LINK_DYNAMIC=ON \
    -D CMAKE_BUILD_TYPE=Release \
    -D CMAKE_CXX_FLAGS_RELEASE="$CXXFLAGS" \
    -D CMAKE_C_FLAGS_RELEASE="$CFLAGS" \
    -S $_pkgname
  make -C build
}

package() {
  install -Dm755 build/c3c "$pkgdir/usr/lib/$_pkgname/c3c"
  cp -r build/lib "$pkgdir/usr/lib/$_pkgname/lib"
  install -d "$pkgdir/usr/bin"
  ln -s "/usr/lib/$_pkgname/c3c" "$pkgdir/usr/bin/c3c"
  install -Dm644 $_pkgname/LICENSE "$pkgdir/usr/share/licenses/$_pkgname/LICENSE"
  install -Dm644 $_pkgname/LICENSE_STDLIB "$pkgdir/usr/share/licenses/$_pkgname/LICENSE_STDLIB"
}

Hi @maxbeaud5

The issue was because of a name change of the shared library in the libxml2 package. I just applied a patch to it into the PKGBUILD.

Please feel free to test it and see if it solves the issue :D Thank you so much.