Arch Linux User Repository

hey, you are not installing the config files in /etc/catnap, this is causing crash.

You were also writing directly to user config dir. please update the pkgbuild. Also openssl is not needed to build

here is fixed one:

# Maintainer: yuki_wastaken <yukiat at proton dot me>
pkgname=catnap-git
_pkgname=catnap
pkgver=r516.11605dd
pkgrel=1
pkgdesc="A minimalistic and fast system fetch written in Nim."
arch=('x86_64' 'aarch64')
url="https://github.com/iinsertNameHere/catnap"
license=('MIT')
groups=()
depends=('pcre' 'glibc')
makedepends=('git' 'nim')
source=('git+https://github.com/iinsertNameHere/catnap.git')
conflicts=($_pkgname)
provides=($_pkgname)
sha256sums=('SKIP')

pkgver() {
    cd "${_pkgname}"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
    cd "${_pkgname}"
    nim release
}

package() {
    cd "${_pkgname}"

    # Install binary
    install -Dm755 bin/catnap "$pkgdir/usr/bin/${_pkgname}"

    # Install configuration files globally
    install -Dm644 config/config.cat "$pkgdir/etc/${_pkgname}/config.cat"
    install -Dm644 config/distros.cat "$pkgdir/etc/${_pkgname}/distros.cat"

    # Install default theme
    install -d "$pkgdir/etc/${_pkgname}/themes"
    install -Dm644 config/themes/catppuccin-mocha.cat "$pkgdir/etc/${_pkgname}/themes/catppuccin-mocha.cat"

    # Install docs and license
    install -Dm644 LICENSE "$pkgdir/usr/share/licenses/${pkgname}/LICENSE"
    install -Dm644 docs/catnap.1 "$pkgdir/usr/share/man/man1/catnap.1"
    install -Dm644 docs/catnap.5 "$pkgdir/usr/share/man/man5/catnap.5"
}

Please set arch to x86_64 (and any additional arches if you can test the build), this package contains ELF files, so can't have arch=('any')

I've updated the PKGBUILD to install the config files.

After installing "~/.config/catnap/" is missing. It should probably contain the files from https://github.com/iinsertNameHere/catnap/tree/main/config