Package Details: check-sieve 0.6-1

Git Clone URL: https://aur.archlinux.org/check-sieve.git (read-only, click to copy)
Package Base: check-sieve
Description: Syntax checker for mail sieves.
Upstream URL: https://github.com/dburkart/check-sieve
Licenses: custom
Submitter: GeoffreyFrogeye
Maintainer: GeoffreyFrogeye
Last Packager: GeoffreyFrogeye
Votes: 1
Popularity: 0.041843
First Submitted: 2015-09-05 17:43
Last Updated: 2019-06-05 20:20

Latest Comments

grawlinson commented on 2021-05-18 00:45

I noticed a few issues, here's an updated PKGBUILD that should fix all that:

# Maintainer: Geoffrey Frogeye <geoffrey+aur@frogeye.fr>
# Contributor: George Rawlinson <grawlinson@archlinux.org>

pkgname=check-sieve
pkgver=0.6
pkgrel=2
pkgdesc="Syntax checker for Sieve scripts"
arch=('i686' 'x86_64')
url="https://github.com/dburkart/check-sieve"
license=('MIT')
depends=('gcc-libs')
checkdepends=('python')
source=("$url/archive/$pkgname-$pkgver.tar.gz")
b2sums=('ceb747f94385f4f5ed883e6503aab1bde82ece472cf41c16f8bdfb039d72068ec80cc2f1f3b3c0374947d2e785504295dbcda252d1d9df165c354eff509ae3ff')

prepare() {
  # rename extracted folder for convenience
  mv "$pkgname-$pkgname-$pkgver" "$pkgname-$pkgver"

  # ensure LDFLAGS are passed to compiler
  sed -i '/\t$(CXX).*/s/$/ $(LDFLAGS)/' "$pkgname-$pkgver/Makefile"
}

build() {
  cd "$pkgname-$pkgver"
  make
}

check() {
  cd "$pkgname-$pkgver"
  make test
}

package() {
  cd "$pkgname-$pkgver"

  make INSTALL_PREFIX="$pkgdir/usr" install

  # license
  install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname" COPYING

  # fix incorrect permissions on library
  chmod 644 "$pkgdir/usr/lib/libchecksieve.a"
}

GeoffreyFrogeye commented on 2019-06-05 20:30

@cgirard Sorry for dismissing your initial comment and thanks for the improvement suggestions. This package really needed some cleanup. namcap still complains about some stuff that would require upstream changes though.

cgirard commented on 2019-02-18 13:14

This package cannot replace itself. This makes no sense (and it's broken).