Arch Linux User Repository

if we are ever more than 1 day out of date - its best to notify me by opening an issue here - https://github.com/erigontech/erigon-pkg

the script which updates both this repo & erigon-bin runs every 4 hours, so if it misses an update, it is probably due to a bug somewhere.

thanks.

I'm doing fine without clang - just works with go (gcc-go).

In addition to my previous point, I was unable to build erigon unless I changed the compiler to clang. Thus adding clang to the makedepends and change the build coommand to the below fixed my issues:

build() {
    cd ${pkgname}

    export CGO_LDFLAGS="${LDFLAGS}"
    export CC=/usr/bin/clang
    export CXX=/usr/bin/clang++
    make all
}

It would be good if the git submodules be downloaded by the PKGBUILD as @zgalvin explained. This is commonly done in Arch Linux packages (for an rather extreme example, see the PyTorch package). In particular, this would avoid unnecessarily redownloading the 300MB+ ethereum tests.

The submodules have changed a little bit since @zgalvin mentioned it, so here is what it would like now:

# Maintainer: Artem Vorotnikov <artem@vorotnikov.me>

pkgname=erigon
pkgver=2022.05.03
pkgrel=1
pkgdesc='Ethereum implementation on the efficiency frontier.'
arch=('x86_64')
url='https://github.com/ledgerwatch/erigon'
license=('GPL3')
depends=('glibc')
makedepends=('git' 'go')
source=("git+https://github.com/ledgerwatch/erigon.git#tag=v${pkgver}"
       "ethereum-tests::git+https://github.com/ethereum/tests"
       "libmdbx::git+https://github.com/torquem-ch/libmdbx.git"
       "erigon-snapshots::git+https://github.com/ledgerwatch/erigon-snapshot.git"
       "trackerslist::git+https://github.com/ngosang/trackerslist.git"
       )
sha256sums=('SKIP'
            'SKIP'
            'SKIP'
            'SKIP'
            'SKIP')

prepare() {
    cd "${pkgname}"
    git submodule init
    git config submodule."tests".url "${srcdir}/ethereum-tests"
    git config submodule."libmdbx".url "${srcdir}/libmdbx"
    git config submodule."turbo/snapshotsync/snapshothashes/erigon-snapshots".url "${srcdir}/erigon-snapshots"
    git config submodule."cmd/downloader/trackers/trackerslist".url "${srcdir}/trackerslist"
}

build() {
    cd ${pkgname}

    export CGO_LDFLAGS="${LDFLAGS}"
    make all
}

package() {
    cd ${pkgname}

    install -Dm755 build/bin/erigon "${pkgdir}"/usr/bin/erigon
    install -Dm755 build/bin/rpcdaemon "${pkgdir}"/usr/bin/erigon-rpcdaemon
    install -Dm755 build/bin/sentry "${pkgdir}"/usr/bin/erigon-sentry
    install -Dm755 build/bin/downloader "${pkgdir}"/usr/bin/erigon-downloader
    install -Dm755 build/bin/txpool "${pkgdir}"/usr/bin/erigon-txpool
    install -Dm755 build/bin/integration "${pkgdir}"/usr/bin/erigon-integration
    install -Dm755 build/bin/hack "${pkgdir}"/usr/bin/erigon-hack
}

There are no real plans to update previous beta, bugfixes aside. Most (all?) users should run snapshot sync-based erigon from now on.

@vorot93 Erigon 2022.04.03-alpha breaks backwards compatibility with previous version. See https://github.com/ledgerwatch/erigon/releases/tag/v2022.04.03

I'd suggest to keep this package for the beta channel and I created a new one named erigon-alpha for the alpha channel.

Thanks zgalvin - your version worked well (although it now needs to be updated with a couple more submodules).

Hello, I made some changes to avoid repeated downloads of the submodule.

# Maintainer: Artem Vorotnikov <artem@vorotnikov.me>

pkgname=erigon
pkgver=2021.10.05
pkgrel=1
pkgdesc='Ethereum implementation on the efficiency frontier.'
arch=('x86_64')
url='https://github.com/ledgerwatch/erigon'
license=('GPL3')
depends=('glibc')
makedepends=('git' 'go')
source=("git+https://github.com/ledgerwatch/erigon.git#tag=v${pkgver}"
        "git+https://github.com/erthink/libmdbx.git"
        "git+https://github.com/ethereum/tests.git"
)
sha256sums=('SKIP'
            'SKIP'
            'SKIP'
)

prepare() {
    cd ${pkgname}
    git submodule init
    git config submodule.libmdbx.url "$srcdir/libmdbx"
    git config submodule.tests.url "$srcdir/tests"
    git submodule update
}

build() {
    cd ${pkgname}
    export CGO_LDFLAGS="${LDFLAGS}"
    make all
}

package() {
    cd ${pkgname}

    install -Dm755 build/bin/erigon "${pkgdir}"/usr/bin/erigon
    install -Dm755 build/bin/rpcdaemon "${pkgdir}"/usr/bin/erigon-rpcdaemon
    install -Dm755 build/bin/integration "${pkgdir}"/usr/bin/erigon-integration
    install -Dm755 build/bin/hack "${pkgdir}"/usr/bin/erigon-hack
}