Package Details: freebsd-mk 10.3_svn296373_6-2

Git Clone URL: https://aur.archlinux.org/freebsd-mk.git (read-only, click to copy)
Package Base: freebsd-mk
Description: FreeBSD makefile templates for bmake
Upstream URL: https://packages.debian.org/stable/freebsd-mk
Licenses: BSD
Submitter: TheZeus121
Maintainer: aperez
Last Packager: aperez
Votes: 0
Popularity: 0.000000
First Submitted: 2018-12-09 13:52 (UTC)
Last Updated: 2025-12-16 12:44 (UTC)

Latest Comments

1ohm commented on 2024-12-20 14:40 (UTC) 

==> ERROR: Failure while downloading http://deb.debian.org/debian/pool/main/f/freebsd-buildutils/freebsd-buildutils_10.3~svn296373-6.debian.tar.xz

Updated PKGBUILD:

# Maintainer: Uko Koknevics <perkontevs AT gmail DOT com>

# Could make a split package with base freebsd-buildutils, but there's a nasty
# cyclic dependency:
# freebsd-buildutils -> freebsd-glue -> freebsd-mk (src in freebsd-buildutils)
_pkgbase=freebsd-buildutils
pkgname=freebsd-mk
_pkgver=10.3~svn296373
_debrel=7
pkgver=10.3_svn296373_7
pkgrel=1
pkgdesc="FreeBSD makefile templates for bmake"
arch=("any")
url="https://packages.debian.org/stable/freebsd-mk"
license=("bsd")
depends=(bmake)
source=(
    "http://deb.debian.org/debian/pool/main/f/${_pkgbase}/${_pkgbase}_${_pkgver}.orig.tar.xz"
    "http://deb.debian.org/debian/pool/main/f/${_pkgbase}/${_pkgbase}_${_pkgver}-${_debrel}.debian.tar.xz"
)
sha256sums=(
    "1b16981e42765813be3811b1eda802dccb673de1c4542ed6476f467b0b21e804"
    "4bf108cd57bba9e44d67b25d89fc9cba46d842a3ca6dafdfaabcba405936eb77"
)

prepare() {
    cd "${srcdir}"
    mv "${_pkgbase}-${_pkgver}/src" src
    rmdir "${_pkgbase}-${_pkgver}"

    # The rest of the patches don't matter bcs we're installing only the
    # makefile includes
    patch -p1 < debian/patches/avoid_defsyspath_collision.diff
}

# No build step

package() {
    cd "${srcdir}"

    cat debian/freebsd-mk.dirs | sed "s|^|${pkgdir}/|" | xargs install -dm755

    install -Dm644 debian/copyright "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"

    for file in src/share/mk/*; do
        install -Dm644 $file "${pkgdir}/usr/share/mk-freebsd/"
    done

    # Debian package didn't include the following files, so if you don't want
    # them for whatever reason, uncomment the following lines:
    # rm "${pkgdir}/usr/share/mk-freebsd/Makefile"
    # rm "${pkgdir}/usr/share/mk-freebsd/local.sys.mk"
    # rm "${pkgdir}/usr/share/mk-freebsd/netbsd-tests.test.mk"
}