Package Details: fsrx 1.0.0-1

Git Clone URL: https://aur.archlinux.org/fsrx.git (read-only, click to copy)
Package Base: fsrx
Description: flow state reading in the terminal
Upstream URL: https://github.com/coloradocolby/fsrx
Licenses: MIT
Submitter: pjvds
Maintainer: pjvds
Last Packager: pjvds
Votes: 0
Popularity: 0.000000
First Submitted: 2022-06-08 17:52 (UTC)
Last Updated: 2022-06-09 14:26 (UTC)

Dependencies (1)

Required by (0)

Sources (1)

Latest Comments

pjvds commented on 2022-06-09 14:28 (UTC)

@yigits: jq was used to filter diagnostic build output but is now removed. License is added now and version is bumped to 1.0.0.

Thanks for the comment!

yigits commented on 2022-06-08 22:27 (UTC) (edited on 2022-06-08 22:30 (UTC) by yigits)

jq is not a makedepend, this conflicts with fsrx-git and license is missing, you can use the following PKGBUILD which follows Rust package guidelines instead:

pkgname=fsrx
pkgver=1.0.0
pkgrel=1
pkgdesc="flow state reading in the terminal"
arch=('x86_64')
url="https://github.com/coloradocolby/fsrx"
license=('MIT')
makedepends=('cargo')
conflicts=(${pkgname}-git)
source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
sha256sums=('5f5a59b66966188a3a647cb958376aabd2c65766791de73ae381b2adc6df8ce0')

prepare() {
  cd "$srcdir/$pkgname-$pkgver"
  cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
}

build() {
  cd "$srcdir/$pkgname-$pkgver"
  export RUSTUP_TOOLCHAIN=stable
  export CARGO_TARGET_DIR=target
  GEN_COMPLETIONS=1 cargo build --frozen --release --all-features
}

package() {
  cd "$srcdir/$pkgname-$pkgver"

  install -Dm0755 -t "$pkgdir/usr/bin/" "target/release/$pkgname"
  install -Dm644 LICENSE.md "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}