Arch Linux User Repository

This does not appear to be a -git package. A -git package should build directly from whatever the latest development head happens to be.

I've provided a new PKGBUILD here with a few changes to better align with Arch's packaging standards (as best I know them).

# Maintainer: Andrew Grechkin <andrew.grechkin@gmail.com>

pkgname=fuse3-p7zip-git
pkgver=2.1.0.r0.g4d4bc7a
pkgrel=1
pkgdesc='fuse3 file system that uses the 7zip library to mount archives'

url='https://github.com/andrew-grechkin/fuse3-p7zip'
arch=(x86_64)
license=(GPL-3.0-or-later)

depends=(fuse3 7zip)
makedepends=(cmake git go-md2man)

source=(git+https://github.com/andrew-grechkin/fuse3-p7zip
        git+https://github.com/ip7z/7zip)

sha256sums=(SKIP SKIP)

prepare() {
    cd fuse3-p7zip
    git submodule init
    git config submodule.3rdparty/7zip.url "$srcdir"/7zip
    git -c protocol.file.allow=always submodule update 3rdparty/7zip
}

pkgver() {
    cd fuse3-p7zip
    git describe --long --tags | sed -E 's/([^-]*-g)/r\1/; s/-/./g'
}

build() {
    cd fuse3-p7zip

    CFLAGS+=" $CPPFLAGS -fmacro-prefix-map=$PWD/=" cmake \
        -D CMAKE_INSTALL_PREFIX=/usr \
        -D CMAKE_BUILD_TYPE=None \
        -B build \
        -S .
    cmake --build build

    go-md2man -in=README.md -out=fuse3-p7zip.1
}

package() {
    cd fuse3-p7zip
    install -Dm0755 build/bin/fuse3-p7zip "$pkgdir"/usr/bin/fuse3-p7zip
    install -Dm0644 fuse3-p7zip.1 "$pkgdir"/usr/share/man/man1/fuse3-p7zip.1
}

I was not able to get the install target to work, either via DESTDIR=$pkgdir cmake --install build or make -C build DESTDIR=$pkgdir install. Instead it just moves the binary over.

Despite an old trick to try keep refs to $srcdir out of the built object it still appears present.

Here are remaining issues found by namcap which you may consider:

fuse3-p7zip-git W: Dependency glibc detected and implicitly satisfied (libraries ['usr/lib/libc.so.6'] needed in files ['usr/bin/fuse3-p7zip'])
fuse3-p7zip-git W: Dependency gcc-libs detected and implicitly satisfied (libraries ['usr/lib/libgcc_s.so.1', 'usr/lib/libstdc++.so.6'] needed in files ['usr/bin/fuse3-p7zip'])
fuse3-p7zip-git W: Dependency included, but may not be needed ('7zip')

Fixed

Fixed. Git is added to makedepends