Package Details: gamerworld 1.1.8-3

Git Clone URL: https://aur.archlinux.org/gamerworld.git (read-only, click to copy)
Package Base: gamerworld
Description: Play games all in one place
Upstream URL: https://gitlab.com/gamerworld/application
Licenses: GPL
Conflicts: gamerworld
Provides: gamerworld
Submitter: gameslayer
Maintainer: gameslayer
Last Packager: gameslayer
Votes: 0
Popularity: 0.000000
First Submitted: 2019-09-05 15:22
Last Updated: 2020-03-26 05:31

Latest Comments

« First ‹ Previous 1 2

yochananmarqos commented on 2019-10-30 15:57

I see. Then the pkgver should be generated by parsing the package.json file. If you remove the -1 from it since that's only for the pkgrel here, this can be used:

EDIT: I found a much more elegant way to do it with node!

pkgver() {
    cd "$srcdir/application"
    node -pe "require('./package.json').version"
}

For now, this can be used. It will remove the -1 from the end since pkgver cannot contain dashes:

pkgver() {
    cd "$srcdir/application"
    node -pe "require('./package.json').version" | head --bytes -3
}

gameslayer commented on 2019-10-30 14:32

The method of versioning comes from my gitlab repo here: https://gitlab.com/gamerworld/application

and the exact version comes from package.json file which is a static version "1.1.4-1" as stated on it and on this AUR package and will only be that version and only use the version of NPM packages stated on that package.json which is based on and will only use Electron 7.0.0.

yochananmarqos commented on 2019-10-30 14:23

That doesn't answer my question, I see no method of versioning. Either way, this package pulls the latest commit from your repo, not a static version.

gameslayer commented on 2019-10-30 14:18

The versioning comes from the original source my Gitlab repo where it is sourced

yochananmarqos commented on 2019-10-30 14:12

You have neither releases nor tags, where is the version coming from?

gameslayer commented on 2019-10-30 05:47

Thanks yochananmarqos but what does the pkg version mean that you used and can I just continue to keep using the current version scheming I have been for simplicity from the package on my Gitlab repo?

yochananmarqos commented on 2019-10-29 15:16

A few things:

  • This should be called gamerworld-git as it's a VCS package, see guidelines.
  • nodejs is not necessary to include as npm depends on it.
  • Use a local NPM cache instead of cluttering the user's home directory, see guidelines.
pkgname=gamerworld-git
_pkgname=GamerWorld
pkgver=r62.6a0e937
pkgrel=1
pkgdesc="Play games all in one place"
arch=('x86_64')
url="https://gitlab.com/gamerworld/application"
license=('GPL')
depends=('nss' 'gtk3' 'libxss')
makedepends=('npm' 'git')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=('git+https://gitlab.com/gamerworld/application.git')
sha256sums=('SKIP')

pkgver() {
    cd "$srcdir/application"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
    cd "$srcdir/application"
    npm --cache "$srcdir/npm-cache" i electron jquery electron-packager
    ./node_modules/.bin/electron-packager .
}

package() {
    cd "$srcdir/application/$_pkgname-linux-x64"
    install -dm755 "$pkgdir/opt/$_pkgname"
    cp -r ./ "$pkgdir/opt/$_pkgname"

    # Link to binary
    install -dm755 "$pkgdir/usr/bin"
    ln -s "/opt/$_pkgname/$_pkgname" "$pkgdir/usr/bin/${pkgname%-git}"

    # Desktop Entry
    install -Dm644 "$srcdir/application/$_pkgname.desktop" \
        "$pkgdir/usr/share/applications/$_pkgname.desktop"
    sed -i s%/usr/share%/opt% "$pkgdir/usr/share/applications/$_pkgname.desktop"
}

yochananmarqos commented on 2019-09-06 15:05

Depends as namcap sees them: depends=(libxss nss gtk3)