Arch Linux User Repository

There is github fork of gnash with build patches: https://github.com/shunonymous/gnash.

PKGBUILD for player, without browser plugin:

pkgname=gnash-git
_gitname=gnash
pkgver=0.8.11.r22402.geac6fd36c
pkgrel=1
pkgdesc="The GNU SWF Player based on GameSWF - git development version"
arch=('i686' 'x86_64')
url="http://www.gnu.org/software/gnash/"
license=('GPL3')
depends=('curl' 'giflib' 'sdl' 'libjpeg' 'libpng' 'libgl' 
  'glu' 'fontconfig' 'cairo' 'ffmpeg' 'jemalloc' 'boost-libs' 
  'gtk2' 'libldap' 'hicolor-icon-theme' 'desktop-file-utils' 'gconf' 
  'gtkglext' 'agg' 'gdk-pixbuf2')
makedepends=('mesa' 'pkgconfig' 'boost' 'git')
provides=('gnash-common' 'gnash-gtk' 'gnash')
conflicts=('gnash-common' 'gnash-gtk' 'gnash')
replaces=('gnash-common' 'gnash-gtk' 'gnash')
options=('!emptydirs')
install=$_gitname.install
backup=('etc/gnashpluginrc')
source=('git+https://github.com/shunonymous/gnash'
        'jemalloc_gnash.patch')
sha256sums=('SKIP'
            '422aad0cf678f8427b1601e41e6440b3526872b640b6ccd3ab93ae656a9a8c8e')

pkgver() {
  cd $_gitname

  echo "0.8.11.r$(git rev-list --count master).g$(git log -1 --format="%h")" 
}

prepare() {
  cd $_gitname

  chmod +x autogen.sh
  ./autogen.sh
}

build() {
  cd $_gitname

#  patch -Np1 -i "${srcdir}/jemalloc_gnash.patch"
#  sed -i 's#${JEMALLOC_CONFIG} --cxxflags#${JEMALLOC_CONFIG} --cflags#g' configure

  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --enable-gui=sdl,gtk \
    --disable-npapi \
    --enable-media=ffmpeg \
    --enable-renderer=all \
    --enable-device=x11

  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0 /g' -e 's/    if test "$export_dynamic" = yes && test -n "$export_dynamic_flag_spec"; then/      func_append compile_command " -Wl,-O1,--as-needed"\n      func_append finalize_command " -Wl,-O1,--as-needed"\n\0/' libtool

  make
}

package() {
  cd $_gitname

  make GCONF_DISABLE_MAKEFILE_SCHEMA_INSTALL=1 DESTDIR="$pkgdir" install install-plugin

  install -m755 -d "$pkgdir/usr/share/gconf/schemas"

  gconf-merge-schema "$pkgdir/usr/share/gconf/schemas/gnash.schemas" --domain gnash \
    "$pkgdir"/usr/share/applications/*.schemas

  rm -f "$pkgdir"/usr/share/applications/*.schemas
}

I think the package also depends on the boost1.69-libs package.

@iamtakingiteasy thank you for the patches. You should adopt the package and integrate in your patches so it builds easier.

Unfortunately, I failed to install xulrunner. It's written on its Wikipedia page that that package is no longer supported.

@iamtakingiteasy thank you, it works :)

Regarding gif error, this patch may help: http://ix.io/20vM

Basically gnash testing only for libgif 5.1 ignoring that there might be newer minor versions.

You also may need to replace FF_INPUT_BUFFER_PADDING_SIZE with AV_INPUT_BUFFER_PADDING_SIZE where it is used in code: http://ix.io/20vO

it fails to build with the following error:

GnashImageGif.cpp: In destructor ‘virtual gnash::image::{anonymous}::GifInput::~GifInput()’:
GnashImageGif.cpp:126:20: error: too few arguments to function ‘int DGifCloseFile(GifFileType*, int*)’
  126 |  DGifCloseFile(_gif);
      |                    ^
In file included from GnashImageGif.cpp:27:
/usr/include/gif_lib.h:185:9: note: declared here
  185 |     int DGifCloseFile(GifFileType * GifFile, int *ErrorCode);
      |         ^~~~~~~~~~~~~
make[2]: *** [Makefile:1316: libgnashbase_la-GnashImageGif.lo] Error 1
make[2]: Leaving directory '/tmp/yaourt-tmp-kbk/aur-gnash-git/src/gnash/libbase'
make[1]: *** [Makefile:1162: all-recursive] Error 1
make[1]: Leaving directory '/tmp/yaourt-tmp-kbk/aur-gnash-git/src/gnash'
make: *** [Makefile:1070: all] Error 2
==> ERROR: A failure occurred in build().
    Aborting...

Minor correction on @zootboy’s comment – the wildcards need to be quoted, otherwise they might be expanded by the shell, resulting in a “paths must precede expression” error from find.

Also, we might as well single-quote the sed script, run it on multiple files at once, and remove an unnecessary option:

find . \( -iname '*.cpp' -o -iname '*.h' \) -exec sed -i 's/FF_INPUT_BUFFER_PADDING_SIZE/AV_INPUT_BUFFER_PADDING_SIZE/' {} +

Quick & dirty fix for the current build failure. Add this after the cd line in prepare():

find . \( -iname *.cpp -o -iname *.h \) -exec sed -r -i "s/FF_INPUT_BUFFER_PADDING_SIZE/AV_INPUT_BUFFER_PADDING_SIZE/" {} \;

do you want to orphan the package, i could take over.

@Rulatir gcc6 is pulled in by xulrunner, which is needed to build the npapi browser plugin. If you don't need that, you can change this line in the PKGBUILD:

--with-npapi-plugindir=/usr/lib/mozilla/plugins \

to this:

--disable-npapi \

and remove xulrunner as a dep to skip those huge builds.