Arch Linux User Repository

@jkraehemann: I've spent some time and made your PKGBUILD better:

pkgname=gsequencer
pkgver=3.2.4
pkgrel=4
pkgdesc="Advanced Gtk+ Sequencer"
arch=('x86_64')
url="https://nongnu.org/gsequencer"
license=('GPL3')
depends=('cairo' 'gdk-pixbuf2' 'glibc' 'harfbuzz' 'libx11' 'libxml2' 'zlib')
makedepends=('alsa-lib' 'atk' 'dssi' 'fftw' 'glib2' 'gobject-introspection'
'gtk3' 'gtk-doc' 'jack' 'ladspa' 'libinstpatch' 'libpulse' 'libsndfile'
'libsoup' 'libutil-linux' 'lv2' 'pango' 'webkit2gtk')
checkdepends=('cunit' 'xorg-server-xvfb')
provides=('libgsequencer.so' 'libags_thread.so' 'libags_server.so'
'libags_gui.so' 'libags_audio.so' 'libags.so')
source=("https://download.savannah.gnu.org/releases/gsequencer/3.2.x/$pkgname-$pkgver.tar.gz")
sha512sums=('64ce01098abaa99f9f8797229adc9f5740bad92272ba4fca8816ad94bb9b3fe3d1e438b4c94ac615db2d15f8ea13e42839c950f01e619ab65395b95c3d83f6a2')
# validpgpkeys=('ECD34CA97E55AE2AF14FBE9F25B4B3AE3388A17A') # key not available on key servers

prepare() {
  cd "$pkgname-$pkgver"
  autoreconf -vfi
}

build() {
  cd "$pkgname-$pkgver"
  export HTMLHELP_XSL=/usr/share/xml/docbook/xsl-stylesheets-1.79.2/htmlhelp/htmlhelp.xsl
  ./configure --prefix='/usr' \
              --docdir='/usr/share/doc/gsequencer-doc' \
              --enable-gtk-doc \
              --enable-gtk-doc-html \
              --enable-single-docdir
  make
  make html
}

check() {
  cd "$pkgname-$pkgver"
  xvfb-run make -k check
}

package() {
  depends+=('libasound.so' 'libatk-1.0.so' 'libfftw3.so' 'libgio-2.0.so'
  'libglib-2.0.so' 'libgmodule-2.0.so' 'libgobject-2.0.so' 'libgthread-2.0.so'
  'libgtk-3.so' 'libgdk-3.so' 'libinstpatch-1.0.so' 'libjack.so'
  'libjavascriptcoregtk-4.0.so' 'libpango-1.0.so' 'libpangocairo-1.0.so'
  'libpulse.so' 'libpulse-mainloop-glib.so' 'libsndfile.so' 'libsoup-2.4.so'
  'libuuid.so' 'libwebkit2gtk-4.0.so')
  cd "$pkgname-$pkgver"
  make DESTDIR="$pkgdir/" install
  make DESTDIR="$pkgdir/" install-html
}

My suggestion would be to install devtools and run extra-x86_64-build for building this package and in case you change anything in the shared library dependency setup to use find-libdeps and find-libprovides on the built package file.