# Maintainer:  jfperini <@jfperini>
# Contributor: jfperini <@jfperini>

pkgname=iradit
pkgver=0.r1.7a8a0f2
pkgrel=1
pkgdesc="iRadit es un proyecto de software libre para el operador de radio."
url="http://www.radit.org/net"
arch=('any')
license=('GPL v3')
install=iradit.install
depends=('qt4' 'taglib' 'lame' 'vorbis-tools' 'radit-essential')
makedepends=('git')
source=("$pkgname"::'git+https://github.com/jfperini/iradit.git')
# Because the sources are not static, skip Git checksum:
md5sums=('SKIP')

pkgver() {

      cd "$srcdir/$pkgname"
      # Use the tag of the last commit
      printf "0.r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}


build()
{

      cd "$srcdir/$pkgname/src"
      qmake-qt4 $pkgname.pro
      make
      
}


package() {

      cd "$srcdir/$pkgname"
      rm -rf {.git,.gitignore,CONTRIBUTORS,COPYING,CREDITS,LICENSE.txt,README.md}

      install -d $pkgdir/{opt/$pkgname,usr/bin}
      cp -a "./LinuxDesktop/"* "$pkgdir/opt/$pkgname"
      cp -u "./launcher/$pkgname" "$pkgdir/usr/bin"

      install -Dm644 "./launcher/$pkgname.svg" "$pkgdir/usr/share/pixmaps/$pkgname.svg"
      install -Dm644 "./launcher/$pkgname.desktop" "$pkgdir/usr/share/applications/$pkgname.desktop"

      # chmod -R ugo+rX "$pkgdir/opt"
      
}