Package Details: jan-appimage 0.5.16-1

Git Clone URL: https://aur.archlinux.org/jan-appimage.git (read-only, click to copy)
Package Base: jan-appimage
Description: An open source alternative to ChatGPT that runs 100% offline on your computer
Upstream URL: https://jan.ai/
Keywords: ai chatgpt llm localai self-hosted
Licenses: AGPL-3.0-only
Conflicts: jan, jan-bin
Provides: jan
Submitter: rbagpksr
Maintainer: redponike
Last Packager: redponike
Votes: 3
Popularity: 0.114202
First Submitted: 2024-04-22 14:09 (UTC)
Last Updated: 2025-03-24 22:10 (UTC)

Latest Comments

Qwerty-Space commented on 2025-08-15 20:03 (UTC)

Any chance of getting an update to this?

Qwerty-Space commented on 2025-08-15 20:01 (UTC)

Updated PKGBUILD:

pkgname=jan-appimage
_name=Jan
pkgver=0.6.8
pkgrel=1
pkgdesc='An open source alternative to ChatGPT that runs 100% offline on your computer'
arch=('x86_64')
url='https://jan.ai/'
license=('AGPL-3.0-only')
depends=('fuse2' 'hicolor-icon-theme' 'zlib')
provides=("jan")
conflicts=("jan-bin" "jan")
options=(!strip)
_appimage="$pkgname-$pkgver.AppImage"
source=("$_appimage::https://github.com/menloresearch/$_name/releases/download/v$pkgver/Jan_0.6.8_amd64.AppImage")
sha256sums=('2421b838d278626fe33099cf258624d1bf8860ab6659fae4f09c4fcb693bde13')
noextract=("$_appimage")

prepare() {
    chmod +x "$_appimage"
    ./"$_appimage" --appimage-extract
}

build() {
    # Adjust .desktop so it will work outside of AppImage container
    sed -i -E "s|Exec=AppRun|Exec=env DESKTOPINTEGRATION=false /usr/bin/$_name|" "squashfs-root/$_name.desktop"

    # Fix permissions; .AppImage permissions are 700 for all directories
    chmod -R a-x+rX squashfs-root/usr
}

package() {
    # AppImage
    install -Dm755 "$srcdir/$_appimage" "$pkgdir/opt/$_name/$_name.AppImage"

    # Desktop file
    install -Dm644 "$srcdir/squashfs-root/$_name.desktop" "$pkgdir/usr/share/applications/$_name.desktop"

    # Icon images
    install -dm755 "$pkgdir/usr/share/"
    cp -a "$srcdir/squashfs-root/usr/share/icons" "$pkgdir/usr/share/"

    # Symlink executable
    install -dm755 "$pkgdir/usr/bin"
    ln -s "/opt/$_name/$_name.AppImage" "$pkgdir/usr/bin/$_name"
}

Updated .SRCINFO:

pkgbase = jan-appimage
    pkgdesc = An open source alternative to ChatGPT that runs 100% offline on your computer
    pkgver = 0.6.8
    pkgrel = 1
    url = https://jan.ai/
    arch = x86_64
    license = AGPL-3.0-only
    depends = fuse2
    depends = hicolor-icon-theme
    depends = zlib
    provides = jan
    conflicts = jan-bin
    conflicts = jan
    noextract = jan-appimage-0.6.8.AppImage
    options = !strip
    source = jan-appimage-0.6.8.AppImage::https://github.com/menloresearch/jan/releases/download/v0.6.8/Jan_0.6.8_amd64.AppImage
    sha256sums = 2421b838d278626fe33099cf258624d1bf8860ab6659fae4f09c4fcb693bde13

pkgname = jan-appimage