Package Details: kindd-git r28.a150bbc-1

Git Clone URL: https://aur.archlinux.org/kindd-git.git (read-only)
Package Base: kindd-git
Description: A Kindful dd gui written in qt quick. (Github version)
Upstream URL: https://github.com/LinArcX/Kindd
Keywords: dd
Licenses: GPL-3.0
Submitter: linarcx
Maintainer: linarcx
Last Packager: linarcx
Votes: 2
Popularity: 1.065946
First Submitted: 2019-04-24 12:34
Last Updated: 2019-04-26 20:47

Latest Comments

yochananmarqos commented on 2019-05-08 16:42

Fixed PKGBUILD:

# Maintainer: LinArcx <linarcx at gmail.com>
pkgname=kindd-git
pkgver=r28.a150bbc
pkgrel=1
pkgdesc=" A Kindful dd gui written in qt quick."
arch=('any')
url="https://github.com/LinArcX/Kindd"
license=('GPL3')
depends=('polkit' 'qt5-quickcontrols2' 'qt5-quickcontrols' 'qt5-graphicaleffects')
makedepends=('git' 'qt5-base')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=("${pkgname%-git}::git+https://github.com/LinArcX/Kindd.git")
sha256sums=('SKIP')

pkgver() {
  cd "$srcdir/${pkgname%-git}"
  ( set -o pipefail
    git describe --long 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
  )
}

build() {
  cd "$srcdir/${pkgname%-git}"
  qmake CONFIG+=debug CONFIG+=qml_debug
  make
}

package() {
  cd "$srcdir/${pkgname%-git}"
  install -Dm755 ./kindd ${pkgdir}/usr/bin/kindd
  install -Dm644 ./appconf/kindd.desktop ${pkgdir}/usr/share/applications/kindd.desktop
  install -Dm644 ./appconf/kindd.svg ${pkgdir}/usr/share/pixmaps/kindd.svg
  install -Dm644 ./LICENSE ${pkgdir}/usr/share/licenses/kindd/LICENSE
}