Arch Linux User Repository

@r0dn3yS

I have a few suggestions for your PKGBUILD:

1. Change license() to be SPDX compliant and reflect the fact that this is a dual-license piece of software: MIT OR Apache-2.0. 2.Add provides and conflicts with ${pkgname::-4}
2. Make the package compliant with Rust package guidelines, as listed on the Arch Wiki. This means, there is a prepare() step where the cargo crates are fetch, and build has the proper envars and build flags
3. Add `export CFLAGS+=" -ffat-lto-objects". This fixes LTO compilation on Rust packages.
4. Install MIT and Apache-2.0 licenses

diff --git a/PKGBUILD b/PKGBUILD
index f82db9d..5a43252 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -2,17 +2,17 @@

 _pkgname=lamzu-cfg
 pkgname="$_pkgname-git"
-pkgver=r38.b0e5424
+pkgver=r56.51c0879
 pkgrel=1
 pkgdesc="Lamzu mouse configuration tool"
 arch=('x86_64')
 url="https://github.com/LeadSun/lamzu-cfg"
 source=("git+$url")
-license=(MIT)
-options=(!lto)
+license=('MIT OR Apache-2.0')
+provides=("${pkgname::-4}")
+conflicts=("${pkgname::-4}")
 sha256sums=('SKIP')
-
-depends=(hidapi)
+depends=(libgcc glibc systemd-libs)
 makedepends=(cargo git)

 pkgver() {
@@ -20,12 +20,23 @@ pkgver() {
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
 }

+prepare() {
+   cd "$srcdir/$_pkgname"
+   export RUSTUP_TOOLCHAIN=stable
+   cargo fetch --target host-tuple
+}
+
 build() {
    cd "$srcdir/$_pkgname"
-   cargo build --release
+   export RUSTUP_TOOLCHAIN=stable
+   export CARGO_TARGET_DIR=target
+   export CFLAGS+=" -ffat-lto-objects"
+   cargo build --frozen --release --all-features
 }

 package() {
    cd "$srcdir/$_pkgname"
-   install -Dm755 target/release/lamzu-cfg "$pkgdir"/usr/bin/lamzu-cfg
+   install -Dm755 target/release/lamzu "$pkgdir"/usr/bin/lamzu-cfg
+   install -Dm644 LICENSE-APACHE "$pkgdir/usr/share/licenses/${pkgname}/License-Apache-2.0"
+   install -Dm644 LICENSE-MIT "$pkgdir/usr/share/licenses/${pkgname}/License-MIT"
 }