Arch Linux User Repository

Heres a working pkgbuild it works for https://github.com/ChrisMalnick/xx3dsfml

# Maintainer: mox <mox at uni-hd de>
# Based on libftd2xx maintained by Chris <alostengineer at narmos org> et al.
pkgname=libftd3xx
pkgver=1.0.14
pkgrel=1
pkgdesc="Library that allows a direct access to a FTDI USB3.0 chip (FT60x) based device. Proprietary FTDI drivers BETA."
arch=('x86_64')
url="http://www.ftdichip.com/"
license=('Proprietary')
depends=('glibc')

# Keep static lib
options=(!strip staticlibs)

filename=(libftd3xx-linux-x86_64-${pkgver}.tgz)
source=(https://ftdichip.com/wp-content/uploads/2023/06/${filename})
md5sums=('c7b0519edd3b271853bc8bc53a6cbe51')

prepare() {
    echo "Extracting the inner package"
    tar -xvzf ${filename}
}

package() {
    # Make required dirs
    mkdir -p ${pkgdir}/usr/{lib,include}/
    mkdir -p ${pkgdir}/usr/include/libftd3xx/
    mkdir -p ${pkgdir}/etc/udev/rules.d

    # Install versioned so file as well as static library
    install -Dm755 ${srcdir}/linux-${CARCH}/${pkgname}.so ${pkgdir}/usr/lib/${pkgname}.so.${pkgver}
    install -m644 ${srcdir}/linux-${CARCH}/${pkgname}-static.a ${pkgdir}/usr/lib/${pkgname}.a

    # Link versioned so file to generic
    ln -sf /usr/lib/${pkgname}.so.${pkgver} "${pkgdir}"/usr/lib/${pkgname}.so

    # Install Headers
    install -m644 "${srcdir}"/linux-${CARCH}/ftd3xx.h "${pkgdir}"/usr/include/libftd3xx/
    install -m644 "${srcdir}"/linux-${CARCH}/Types.h "${pkgdir}"/usr/include/libftd3xx/

    # Install udev rules
    install -D -m755 "${srcdir}"/linux-${CARCH}/51-ftd3xx.rules "${pkgdir}"/etc/udev/rules.d/51-ftd3xx.rules
}

@mox - libusbx (a dependency) is no longer available in either the AUR or core repositories.