Package Details: libnotify-git 0.8.4.r0.570982f-1

Git Clone URL: https://aur.archlinux.org/libnotify-git.git (read-only, click to copy)
Package Base: libnotify-git
Description: Library for sending desktop notifications
Upstream URL: https://gitlab.gnome.org/GNOME/libnotify
Licenses: LGPL-2.1-or-later
Conflicts: libnotify
Provides: libnotify
Submitter: Florian
Maintainer: Florian
Last Packager: Florian
Votes: 0
Popularity: 0.000000
First Submitted: 2022-06-26 10:48 (UTC)
Last Updated: 2025-02-23 19:01 (UTC)

Required by (1757)

Sources (1)

Latest Comments

Florian commented on 2025-02-23 19:01 (UTC)

Thank for the work! Added to the PKGBUILD.

Antiz commented on 2025-02-22 14:52 (UTC) (edited on 2025-02-22 14:53 (UTC) by Antiz)

Hi,

This PKGBUILD doesn't have any dependency declared and is generally outdated. It will fail to build in a clean chroot (and most likely outside of a clean chroot as well).

Here's an updated and functional PKGBUILD:

# Maintainer: Florian Dejonckheere <florian at floriandejonckheere dot be>

pkgname=libnotify-git
_pkgname=libnotify
pkgver=0.8.4.r0.570982f
pkgrel=1
pkgdesc="Library for sending desktop notifications"
arch=('i686' 'x86_64')
license=('LGPL-2.1-or-later')
url='https://gitlab.gnome.org/GNOME/libnotify'
depends=('gcc-libs' 'gdk-pixbuf2' 'glib2' 'glibc')
makedepends=('docbook-xsl' 'gi-docgen' 'git' 'glib2-devel' 'gobject-introspection' 'gtk3' 'meson' 'xmlto')
conflicts=("${_pkgname}")
provides=("${_pkgname}")
source=("git+${url}.git")
sha256sums=('SKIP')

pkgver() {
  cd "${_pkgname}"

  printf "%s" "$(git describe --long | sed 's/\([^-]*-\)g/r\1/;s/-/./g')"
}

build() {
  arch-meson "${_pkgname}" build
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs
}

package() {
  meson install -C build --destdir "${pkgdir}"
}

git diff:

diff --git a/PKGBUILD b/PKGBUILD
index a60e6fe..7585cea 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -2,19 +2,18 @@

 pkgname=libnotify-git
 _pkgname=libnotify
-pkgver=0.8.2.r0.69aff6e
+pkgver=0.8.4.r0.570982f
 pkgrel=1
 pkgdesc="Library for sending desktop notifications"
 arch=('i686' 'x86_64')
-license=('GPL')
+license=('LGPL-2.1-or-later')
 url='https://gitlab.gnome.org/GNOME/libnotify'
-depends=()
-makedepends=('pkgconfig' 'meson' 'xmlto' 'git' 'gobject-introspection' 'gtk-doc' 'gnome-common' 'gi-docgen')
-options=('!libtool')
+depends=('gcc-libs' 'gdk-pixbuf2' 'glib2' 'glibc')
+makedepends=('docbook-xsl' 'gi-docgen' 'git' 'glib2-devel' 'gobject-introspection' 'gtk3' 'meson' 'xmlto')
 conflicts=("${_pkgname}")
-provides=("${_pkgname}=0.7.12")
-source=("${_pkgname}::git+https://gitlab.gnome.org/GNOME/${_pkgname}.git")
-md5sums=('SKIP')
+provides=("${_pkgname}")
+source=("git+${url}.git")
+sha256sums=('SKIP')

 pkgver() {
   cd "${_pkgname}"
@@ -22,22 +21,15 @@ pkgver() {
   printf "%s" "$(git describe --long | sed 's/\([^-]*-\)g/r\1/;s/-/./g')"
 }

-prepare() {
-  cd "${_pkgname}"
-
-  meson -Dprefix=/usr build
-}
-
 build() {
-  cd "${_pkgname}"
-
+  arch-meson "${_pkgname}" build
   meson compile -C build
 }

-package() {
-  cd "${_pkgname}"
-
-  echo ${pkgdir}
+check() {
+  meson test -C build --print-errorlogs
+}

-  DESTDIR=${pkgdir} meson install -C build
+package() {
+  meson install -C build --destdir "${pkgdir}"
 }