Package Details: libwireplumber-git 0.5.4.r0.gdc6694f-1

Git Clone URL: https://aur.archlinux.org/wireplumber-git.git (read-only, click to copy)
Package Base: wireplumber-git
Description: Session / policy manager implementation for PipeWire - client library
Upstream URL: https://gitlab.freedesktop.org/pipewire/wireplumber
Keywords: pipewire session wireplumber
Licenses: MIT
Conflicts: libwireplumber
Provides: libwireplumber, libwireplumber-0.5.so
Submitter: 1ace
Maintainer: bin (PedroHLC)
Last Packager: PedroHLC
Votes: 3
Popularity: 0.000000
First Submitted: 2020-05-08 14:21 (UTC)
Last Updated: 2024-06-26 20:58 (UTC)

Latest Comments

1 2 3 Next › Last »

PedroHLC commented on 2024-01-15 19:36 (UTC)

I can't add co-maintainers, but you are welcomed to add PRs to https://github.com/chaotic-aur/pkgbuild-wireplumber-git, and I'll push it back here.

yrlf commented on 2024-01-15 19:07 (UTC)

@hayao: this is due to the wireplumber package in the repos having been split into wireplumber and libwireplumber a while ago. Since this needs quite a lot of changes to the PKGBUILD I have instead started from scratch with the repo version of the PKGBUILD and have flagged the package out of date.

Additionally, since 0.4.81 the version for the .so is no longer in sync with the pkgver, due to 0.4.81 being a prerelease for 0.5.x.

Below is an updated PKGBUILD that conforms to the new packaging and builds with 0.4.81.

@bin: If you don't want to maintain this package any more, I can take over and become maintainer for this package.

--- updated PKGBUILD below ---

# Maintainer: Ferdinand Bachmann <ferdinand.bachmann@yrlf.at>
# Contributor: David Runge <dvzrv@archlinux.org>
# Contributor: Jan Alexander Steffens (heftig) <heftig@archlinux.org>

_pkgbase=wireplumber
pkgbase=wireplumber-git
pkgname=(
  wireplumber-git
  libwireplumber-git
)
pkgver=0.4.81.r22.g6f3eb329
pkgrel=1
pkgdesc="Session / policy manager implementation for PipeWire"
url="https://pipewire.pages.freedesktop.org/wireplumber/"
arch=(x86_64)
license=(MIT)
makedepends=(
  doxygen
  git
  glib2
  gobject-introspection
  graphviz
  lua
  meson
  pipewire
  python-lxml
  systemd
)
checkdepends=(pipewire-audio)
source=("git+https://gitlab.freedesktop.org/pipewire/$_pkgbase.git")
b2sums=('SKIP')

pkgver() {
  cd $_pkgbase
  git describe --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  cd $_pkgbase
}

build() {
  local meson_options=(
    -D doc=disabled
    -D elogind=disabled
    -D system-lua=true
  )

  arch-meson $_pkgbase build "${meson_options[@]}"
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs
}

_pick() {
  local p="$1" f d; shift
  for f; do
    d="$srcdir/$p/${f#$pkgdir/}"
    mkdir -p "$(dirname "$d")"
    mv "$f" "$d"
    rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
  done
}

_ver=0.5

package_wireplumber-git() {
  depends=(
    "libwireplumber-git=$pkgver-$pkgrel"
    libsystemd.so
    lua
    pipewire
  )
  provides=(pipewire-session-manager "wireplumber=$pkgver")
  conflicts=(pipewire-media-session wireplumber)
  install=wireplumber.install

  meson install -C build --destdir "$pkgdir"

  (
    cd "$pkgdir"

    _pick libw usr/lib/libwireplumber-$_ver.so*
    _pick libw usr/lib/girepository-1.0
    _pick libw usr/lib/pkgconfig
    _pick libw usr/include
    _pick libw usr/share/gir-1.0
  )

  install -Dt "$pkgdir/usr/share/doc/$pkgname" -m644 $_pkgbase/{NEWS,README}*
  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 $_pkgbase/LICENSE
}

package_libwireplumber-git() {
  pkgdesc+=" - client library"
  depends=(
    libg{lib,module,object,io}-2.0.so
    libpipewire-0.3.so
  )
  provides=(libwireplumber-$_ver.so "libwireplumber=$pkgver")
  conflicts=(libwireplumber)

  mv libw/* "$pkgdir"

  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 $_pkgbase/LICENSE
}

# vim:set sw=2 sts=-1 et:

hayao commented on 2023-09-01 14:21 (UTC)

This package will conflicts with libwireplumber

bin commented on 2022-03-21 15:52 (UTC)

robertfoster, JackMacWindows, lucasrizzini: Thanks for raising this; fixed.

lucasrizzini commented on 2022-03-20 12:25 (UTC)

+1 @robertfoster, needed to install python-lxml manually to let it build.

JackMacWindows commented on 2022-01-20 05:25 (UTC)

+1 @robertfoster, needed to install python-lxml manually to let it build.

robertfoster commented on 2022-01-09 15:19 (UTC)

Thanks for this

python-lxml is missing as makedep

Regards

bin commented on 2022-01-02 05:23 (UTC)

@nyanpasu64 Fixed, thanks.

nyanpasu64 commented on 2021-12-06 15:12 (UTC)

hotdoc has been removed from the upstream wireplumber package's dependency list (https://github.com/archlinux/svntogit-packages/commit/3587e25ac4451ab2d658357570a3c9c9e1c66bb5#diff-37538beb61ff63edebbf735dfcf39e5d732f49183d6beb097169d971875ca422), can you remove it from here as well?

1 2 3 Next › Last »