Arch Linux User Repository

@bhyoo: Done!

* Getting build dependencies for wheel...

Traceback (most recent call last):
  File "/usr/lib/python3.14/site-packages/pyproject_hooks/_impl.py", line 402, in _call_hook
    raise BackendUnavailable(
    ...<4 lines>...
    )
pyproject_hooks._impl.BackendUnavailable: Cannot import 'uv_build'

ERROR Backend 'uv_build' is not available.

Please add python-uv-build as make dependency

After installing this package my computer still complain that the litellm is missing dependency. The other solution works for me:

sudo pacman -S uv

uv tool install "litellm[proxy]"

real danger of package compromised https://futuresearch.ai/blog/litellm-pypi-supply-chain-attack/

FYI: Maintainers, do not update litellm. The upstream repo and its owner's account are compromized as of at least today.

@Dominiquini I think you need to use the dependencies from pyproject.toml not from requirements.txt.

@Ataraxy There is no litellm-proxy package even in PyPI. There is litellm-proxy-extras that need to be provided separately.

Note that litellm-proxy is a command not a package.

I cobbled together a required package for litellm-proxy: https://aur.archlinux.org/packages/python-fastapi-sso-git

Please update your PKGBUILD based on the below to enable the litellm-proxy that this package provides.

It will build both litellm and litellm-proxy (because that's a limitation of pkgbuild). However, if using paru, only the one you specify on its command line will be installed.

The commented-out lines are the packages that I couldn't find in AUR/extra, mentioned in an earlier comment.

# Maintainer: AlphaJack <alphajack at tuta dot io>
# Contributor: Darius Niminenn <root at dnim dot dev>
# Contributor: Sir-Photch <sir-photch@posteo.me>
# Maintainer: Mohamed Amine Zghal (medaminezghal) <medaminezghal at outlook dot com>

pkgbase=litellm
pkgname=('litellm' 'litellm-proxy')
pkgver=1.81.6
pkgrel=1
pkgdesc='Library to easily interface with LLM API providers.'
arch=(any)
url='https://github.com/BerriAI/litellm'
license=('MIT')

# --- DEPENDENCY DEFINITIONS ---

# 1. Base Core Dependencies (Required by ALL)
_base_depends=(
    'python'
    'python-fastuuid'
    'python-httpx'
    'python-openai'
    'python-dotenv'
    'python-tiktoken'
    'python-importlib-metadata'
    'python-tokenizers'
    'python-click'
    'python-rich'
    'python-jinja'
    'python-aiohttp'
    'python-aioboto3'
    'python-tenacity'
    'python-pydantic'
    'python-jsonschema'
    'python-websockets'
)

# 2. Proxy Dependencies (Required by litellm-proxy; Optional for litellm)
# WARNING: 'litellm-proxy-extras' and 'litellm-enterprise' may require manual AUR creation/pip install
_proxy_deps=(
    'gunicorn'
    # 'litellm-enterprise'
    # 'litellm-proxy-extras'
    # 'python-anthropic'
    'python-anyio'
    'python-apscheduler'
    # 'python-async_generator'
    # 'python-azure-ai-contentsafety'
    # 'python-azure-identity'
    # 'python-azure-keyvault'
    # 'python-azure-storage-blob'
    # 'python-azure-storage-file-datalake'
    'python-backoff'
    'python-boto3'
    'python-cryptography'
    # 'python-ddtrace'
    # 'python-detect-secrets'
    'python-fastapi'
    # 'python-fastapi-sso'
    'python-google-auth'
    # 'python-google-cloud-aiplatform'
    # 'python-google-genai'
    # 'python-google-generativeai'
    # 'python-langfuse'
    # 'python-mangum'
    # 'python-mcp'
    # 'python-opentelemetry-api'
    # 'python-opentelemetry-exporter-otlp'
    # 'python-opentelemetry-sdk'
    'python-oauthlib'
    'python-orjson'
    'python-pillow'
    'python-polars'
    'python-prometheus_client'
    'python-pyjwt'
    'python-pynacl'
    'python-python-multipart'
    'python-pyyaml'
    'python-redis'
    'python-requests'
    # 'python-rq'
    'python-sentry_sdk'
    'python-tzdata'
    'python-uvloop'
    'uvicorn'
)

# 3. Extra Optional Dependencies (Optional for BOTH)
_other_optdepends=(
    'python-azure-keyvault-secrets: extra_proxy'
    'python-diskcache: caching'
    'python-google-cloud-iam: extra_proxy'
    'python-google-cloud-kms: extra_proxy'
    'python-mlflow: mlflow'
    'python-numpydoc: utils'
    'python-prisma: extra_proxy'
    'python-redisvl: extra_proxy'
    'python-resend: extra_proxy'
    'python-semantic-router: semantic-router'
)

makedepends=('python-poetry-core' 'python-build' 'python-installer' 'python-wheel')
source=("https://files.pythonhosted.org/packages/source/${pkgbase::1}/$pkgbase/$pkgbase-$pkgver.tar.gz")
sha256sums=('f02b503dfb7d66d1c939f82e4db21aeec1d6e2ed1fe3f5cd02aaec3f792bc4ae')

build() {
  cd "$srcdir"/$pkgbase-$pkgver
  python -m build --wheel --no-isolation
}

# --- DRY Helper Function ---
_install_common() {
  cd "$srcdir"/$pkgbase-$pkgver
  # Uses the variable $pkgdir which is set dynamically by makepkg for each split function
  python -m installer --destdir="$pkgdir" dist/*.whl
}

package_litellm() {
  pkgdesc='Library to easily interface with LLM API providers (Light/Client only)'

  depends=("${_base_depends[@]}")

  # Bash Substitution: Append ': proxy' to every item in _proxy_deps
  optdepends=("${_proxy_deps[@]/%/: proxy}" "${_other_optdepends[@]}")

  provides=("${pkgbase}")
  conflicts=("${pkgbase}-proxy")

  _install_common
}

package_litellm-proxy() {
  pkgdesc='Library to easily interface with LLM API providers (Full Proxy Server)'

  depends=("${_base_depends[@]}" "${_proxy_deps[@]}")

  optdepends=("${_other_optdepends[@]}")

  provides=("${pkgbase}" "${pkgbase}-proxy")
  conflicts=("${pkgbase}")

  _install_common
}

Please run:

namcap litellm-*any.pkg.tar.zst | grep ' E: '

This will show things such as:

litellm E: Uncommon license identifiers such as 'MIT' require license files below /usr/share/licenses/litellm/ or switching to common licens
e identifiers. Found 0/1 required license files.
litellm E: Dependency python-protobuf detected and not included (python modules ['google.protobuf.struct_pb2.Value', 'google.protobuf.json_f
ormat'] needed in files ['usr/lib/python3.14/site-packages/litellm/llms/vertex_ai/vertex_ai_non_gemini.py'])

Many of the optional dependencies don't exist as packages.

Please remove them or mention that these will need to be installed via pip or some non-pacman method.

(Below, I set them to be required to get a working litellm-proxy)

:: unable to satisfy dependency 'litellm-enterprise' required by litellm-proxy
:: unable to satisfy dependency 'litellm-proxy-extras' required by litellm-proxy
:: unable to satisfy dependency 'python-anthropic' required by litellm-proxy
:: unable to satisfy dependency 'python-async_generator' required by litellm-proxy
:: unable to satisfy dependency 'python-azure-ai-contentsafety' required by litellm-proxy
:: unable to satisfy dependency 'python-azure-identity' required by litellm-proxy
:: unable to satisfy dependency 'python-azure-keyvault' required by litellm-proxy
:: unable to satisfy dependency 'python-azure-storage-blob' required by litellm-proxy
:: unable to satisfy dependency 'python-azure-storage-file-datalake' required by litellm-proxy
:: unable to satisfy dependency 'python-ddtrace' required by litellm-proxy
:: unable to satisfy dependency 'python-detect-secrets' required by litellm-proxy
:: unable to satisfy dependency 'python-fastapi-sso' required by litellm-proxy
:: unable to satisfy dependency 'python-google-cloud-aiplatform' required by litellm-proxy
:: unable to satisfy dependency 'python-google-genai' required by litellm-proxy
:: unable to satisfy dependency 'python-google-generativeai' required by litellm-proxy
:: unable to satisfy dependency 'python-langfuse' required by litellm-proxy
:: unable to satisfy dependency 'python-mangum' required by litellm-proxy
:: unable to satisfy dependency 'python-mcp' required by litellm-proxy
:: unable to satisfy dependency 'python-opentelemetry-api' required by litellm-proxy
:: unable to satisfy dependency 'python-opentelemetry-exporter-otlp' required by litellm-proxy
:: unable to satisfy dependency 'python-opentelemetry-sdk' required by litellm-proxy
:: unable to satisfy dependency 'python-rq' required by litellm-proxy

NOTE: I did not check the non-proxy optdepends.