Package Details: magicpodscore-git 2.0.4.r0.g565cbba-1

Git Clone URL: https://aur.archlinux.org/magicpodscore-git.git (read-only, click to copy)
Package Base: magicpodscore-git
Description: A command-line utility for managing AirPods, Beats, and Galaxy Buds.
Upstream URL: https://github.com/steam3d/MagicPodsCore
Keywords: airpods magicpods
Licenses: GPL-3.0-only
Submitter: Spoorloos
Maintainer: Spoorloos
Last Packager: Spoorloos
Votes: 2
Popularity: 0.144977
First Submitted: 2026-01-02 13:30 (UTC)
Last Updated: 2026-01-02 13:30 (UTC)

Latest Comments

JamesFromFL commented on 2026-03-24 16:09 (UTC) (edited on 2026-03-24 16:09 (UTC) by JamesFromFL)

Current PKGBUILD fails because it uses Docker as the build tool and requires the Docker daemon to be running. Replaced with a native CMake build, which works out of the box.

Updated PKGBUILD:

pkgname='magicpodscore-git'
pkgver=2.0.7.r1.g88e76bc
pkgrel=1
pkgdesc='A command-line utility for managing AirPods, Beats, and Galaxy Buds.'
url='https://github.com/steam3d/MagicPodsCore'
arch=('x86_64')
license=('GPL-3.0-only')
depends=('bluez-libs' 'glibc' 'libpulse' 'openssl' 'systemd-libs' 'zlib')
makedepends=('git' 'cmake' 'ninja')
source=(
    'git+https://github.com/steam3d/MagicPodsCore.git'
)
sha256sums=('SKIP')

pkgver() {
    cd "$srcdir/MagicPodsCore"
    git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
    cmake -B "$srcdir/build" -S "$srcdir/MagicPodsCore" \
        -G Ninja \
        -DCMAKE_BUILD_TYPE=Release
    cmake --build "$srcdir/build"
}

package() {
    install -Dm755 "$srcdir/build/magicpodscore" "$pkgdir/usr/bin/magicpodscore"
}