Arch Linux User Repository

@Misaka13514, done. Thank you.

FileTable.dat is missing. This package updates every time I query, please update the pkgver. Please add provides and conflicts. Thanks for maintaining!

@testcore, I checked - the build and installation work flawlessly. Could you please provide more information what the error is? The package does not have a buildtime dependency.

This is now failing on a missing dependency "buildtime". Where exactly should that be installed from? Unclear if it's supposed to be an arch pkg or what; can't find it in the main repos, AUR, or with PIP.

Thank you, @m3thodic. I have updated the package.

Here is an updated PKGBUILD that symlinks MEA.py instead of patching files:

# Maintainer: Alex Sarum <rum.274.4 at gmail dot com>
# Contributor: Gavin Lloyd <gavinhungry@gmail.com>
# Contributor: Bailey Fox <bfox200012@gmail.com>

pkgname=meanalyzer-git
pkgver=1.282.0.r295.r0.g5f7ae54
pkgrel=1
pkgdesc='Intel Management Engine firmware analysis tool'
arch=('any')
url='https://github.com/platomav/MEAnalyzer'
_branch='master'
license=('GPL3')
depends=('python-colorama' 'python-crccheck' 'python-pltable')
makedepends=('dos2unix' 'git')
source=("${pkgname}::git+${url}#branch=${_branch}"
        'change-mea_dir.patch'
        'db-location.patch')
sha256sums=('SKIP'
            '8d77dc46728f5dc3b396910f2626f3508b28cfd76de77890e27e3c55b1c09e85'
            'cb9ee47ec3e6158762e9f1669cb35599c15b11202f9ff29234fb437e26d5faa8')

pkgver() {
  cd "${srcdir}/${pkgname}"
  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  cd "${srcdir}/${pkgname}"
  dos2unix MEA.py
}

package() {
  cd "${srcdir}/${pkgname}"
  install -Dm644 MEA.dat "${pkgdir}"/usr/lib/meanalyzer/MEA.dat
  install -Dm644 Huffman.dat "${pkgdir}"/usr/lib/meanalyzer/Huffman.dat
  install -Dm755 MEA.py "${pkgdir}"/usr/lib/meanalyzer/MEA.py

  install -dm755 "${pkgdir}"/usr/bin
  ln -s /usr/lib/meanalyzer/MEA.py "${pkgdir}"/usr/bin/meanalyzer
}

I'm unsure what the problem is but the AUR package fails but cloning the source git repository works fine. The error:

Switched to a new branch 'makepkg'
==> Starting prepare()...
patching file MEA.py
Hunk #1 FAILED at 7654 (different line endings).
Hunk #2 FAILED at 9011 (different line endings).
2 out of 2 hunks FAILED -- saving rejects to file MEA.py.rej

Also, python-pltable doesn't seem to work with the latest meanalyzer while python-pltable-git does.

@egrupled thanks, this seems to work for me

python-pltable-git is available in AUR: https://aur.archlinux.org/packages/python-pltable-git/

You also need to add epoch=1 to PKGBUILD and refresh version as current AUR version is detected as newer than building last commit form git.

Give me a bit to fix this. Apparently PTable was renamed to PLTable, which is now provided on pypi. So I'm going to create a new package for PLTable and list it as a dependency.