Arch Linux User Repository

The "provides" array is a way to indicate to pacman which additional dependencies a package can satisfy. It should never contain $pkgname because it is already implicit that all packages satisfy dependencies on themselves. In the case of VCS packages, you should include the package name without the VCS suffix ("miraclecast" in this case) because the VCS package is normally functionally equivalent to the non-VCS version for dependency resolution. In general, for "foo-git", "provides=(foo)" and "conflicts=(foo)" mean that "foo-git" can be used in place of "foo" but not alongside it, usually due to conflicting files.

The "replaces" array should also be removed. That is reserved for packages that supersede other packages (e.g. for name changes). VCS packages provide alternatives, but they do not supersede their non-VCS counterparts.

This has always been our policy. You do not need to remove the $_name variable. It's common practice to define it and then use it throughout the PKGBUILD. Please see my suggestion below.

As for the package version, it should be updated automatically when you build the package due to the pkgver function. Whenever that's updated, you can reset the pkgrel to 1. The only time you would need to bump the pkgrel is if you update the PKGBUILD without changing the pkgver, which may happen if upstream is not very active.

# Maintainer: Alberto Fanjul <albertofanjul@gmail.com>
_name=miraclecast
pkgname=$_name-git
pkgver=221.36be37e
pkgrel=2
pkgdesc="MiracleCast provides software to connect external monitors to your system via Wifi. It is compatible to Miracast. Link-management works, everything else is still being worked on. Replaces openwfd. Contribute on https://github.com/albfan/aur-miraclecast"
arch=('i686' 'x86_64' 'armv6h' 'armv7h')
url="https://github.com/albfan/$_name"
license=('GPL')
depends=(git "systemd>=221" "python3" "glib2")
provides=("$_name")
conflicts=("$_name")
backup=(etc/dbus-1/system.d/org.freedesktop.miracle.conf)
source=("$_name::git+https://github.com/albfan/miraclecast.git#branch=master")
md5sums=('SKIP')

build() {
  cd "$srcdir/$_name"
  ./autogen.sh
  ./configure --prefix=/usr --sysconfdir=/etc
  make
}

check() {
  cd "$srcdir/$_name"
  make -k check
}

package() {
  cd "$srcdir/$_name"
  make DESTDIR="$pkgdir/" install
}

pkgver() {
  cd "$srcdir/$_name"
  echo $(git rev-list --count HEAD).$(git rev-parse --short HEAD)
}

I was explicitly told to provide a vcs package and provide miraclecast-git that do conflict with a possible miraclecast from releases. Is the policy changing?

If I remove the $name I will have to remove that on build all steps too right? Why is that needed?

Should I set package version as 1 always for a vcs package?

From https://wiki.archlinux.org/title/Arch_User_Repository

Note: Packages in the AUR assume that the base-devel group is installed, i.e. they do not list the group's members as build dependencies explicitly.

https://archlinux.org/groups/x86_64/base-devel/

Was not able to install aur/miraclecast-git 221.36be37e-2 on the fly on 5.13.19-2-MANJARO #1 SMP PREEMPT Sun Sep 19 21:31:53 UTC 2021 x86_64 GNU/Linux. autoreconf from package autoconf and aclocal from package automake were missing. May add it to the requirements?

diff with the necessary changes:

diff --git a/PKGBUILD b/PKGBUILD
index bc4f634..a9876e4 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,18 +1,17 @@
 # Maintainer: Alberto Fanjul <albertofanjul@gmail.com>
 pkgname=miraclecast-git
 _name=miraclecast
-pkgver=221.36be37e
-pkgrel=2
+pkgver=284.0481252
+pkgrel=1
 pkgdesc="MiracleCast provides software to connect external monitors to your system via Wifi. It is compatible to Miracast. Link-management works, everything else is still being worked on. Replaces openwfd. Contribute on https://github.com/albfan/aur-miraclecast"
 arch=('i686' 'x86_64' 'armv6h' 'armv7h')
 url="https://github.com/albfan/miraclecast"
 license=('GPL')
 depends=(git "systemd>=221" "python3" "glib2")
-provides=("miraclecast-git")
-replaces=("miraclecast")
+provides=("miraclecast")
 conflicts=("miraclecast")
 backup=(etc/dbus-1/system.d/org.freedesktop.miracle.conf)
-source=("$_name::git+https://github.com/albfan/miraclecast.git#branch=master")
+source=("git+https://github.com/albfan/miraclecast.git#branch=master")
 md5sums=('SKIP')

 build() {

In build() before executing ./autogen.sh, I had to call dos2unix on multiple files (to make it compile):

build() {
  cd "$srcdir/$_name"
  dos2unix ./autogen.sh
  find . -name \*.m4|xargs dos2unix
  find . -name \*.ac|xargs dos2unix
  find . -name \*.am|xargs dos2unix
  ./autogen.sh
  ./configure --prefix=/usr --sysconfdir=/etc
  make
}

The entry in the provides array should be "miraclecast", not "miraclecast-git".

Thanks @servimo, fixed

package "git-core" does not exist