Package Details: moonlight-qt-qiin2333 6.21.46-1

Git Clone URL: https://aur.archlinux.org/moonlight-qt-qiin2333.git (read-only, click to copy)
Package Base: moonlight-qt-qiin2333
Description: GameStream client for PCs (qiin2333 fork with extra features)
Upstream URL: https://github.com/qiin2333/moonlight-qt
Licenses: GPL-3.0-or-later
Conflicts: moonlight-qt
Provides: moonlight-qt
Submitter: Clansty
Maintainer: Clansty
Last Packager: Clansty
Votes: 1
Popularity: 0.41
First Submitted: 2026-04-06 05:24 (UTC)
Last Updated: 2026-04-13 14:57 (UTC)

Latest Comments

picdupe commented on 2026-04-13 13:48 (UTC) (edited on 2026-04-13 13:49 (UTC) by picdupe)

当前 PKGBUILD 存在以下问题，编译会失败：

  1. depends 缺少 qt6-multimedia（编译报错 Unknown module(s) in QT: multimedia）
  2. makedepends 缺少 qt6-tools（qmake6 命令找不到）
  3. prepare() 中的 qmake6 应该移到 build()，且 PREFIX 不应使用 $pkgdir
  4. package() 应使用 INSTALL_ROOT="$pkgdir"

建议更新为以下 PKGBUILD：

pkgname=moonlight-qt-qiin2333
pkgver=6.21.46
pkgrel=1
pkgdesc='GameStream client for PCs (qiin2333 fork with extra features)'
arch=('x86_64')
license=('GPL-3.0-or-later')
url='https://github.com/qiin2333/moonlight-qt'
depends=('qt6-base' 'qt6-declarative' 'qt6-svg' 'qt6-multimedia' 'ffmpeg' 'sdl2_ttf' 'sdl2')
makedepends=('git' 'vulkan-headers' 'qt6-tools')
optdepends=('libva-intel-driver: hardware acceleration for Intel GPUs GMA 4500 (2008) up to Coffee Lake (2017)'
  'intel-media-driver: hardware acceleration for Intel GPUs starting from Broadwell (2014) and newer (e.g. Intel Arc)')
provides=('moonlight-qt')
conflicts=('moonlight-qt')
source=("git+https://github.com/qiin2333/moonlight-qt.git#tag=v${pkgver}")
sha256sums=('SKIP')

prepare() {
  cd moonlight-qt
  git submodule update --init --recursive --depth 1
}

build() {
  cd moonlight-qt
  qmake6 PREFIX=/usr moonlight-qt.pro
  make release
}

package() {
  cd moonlight-qt
  make INSTALL_ROOT="$pkgdir" install
}

已在本地测试通过，可以正常编译和运行。麻烦更新一下，谢谢！