Arch Linux User Repository

@VIL i had to include netbird.wasm in the package to make it work. This is how I've adjusted the PKBUILD

# Maintainer: Vladislav Minakov <v@minakov.pro>

pkgname=netbird-dashboard
pkgver=2.23.0
_nb_wasm_ver=0.60.7
pkgrel=2
pkgdesc="UI for NetBird's Management service (ships browser WASM for WebUI SSH)."
arch=('any')
url="https://github.com/netbirdio/dashboard"
license=('MIT')
optdepends=('nginx: reverse-proxy')
makedepends=('nodejs' 'npm')


source=(
  "$pkgname-$pkgver.tar.gz::https://github.com/netbirdio/dashboard/archive/refs/tags/v${pkgver}.tar.gz"
  "netbird.wasm::https://github.com/netbirdio/netbird/releases/download/v${_nb_wasm_ver}/netbird_${_nb_wasm_ver}.wasm"
  "local-config.json"
)

sha512sums=('5fa99669960a2ab5b088834e4f55e0672f4bd9c30d45134eea3def4af4356d9d53cf5dc24757ec1c3da4ed95a36dbdc648bbde6c0cc80ac85bea2279ef91f4eb'
            '17e26f5575db0cf3e57ce857556d2c9a5be54f625d30fef6fa3d2212bb0b64538b842b1e5d9b9e6ccb428b611d397a5cc120203bdf37a297e5dbe3ea3557c226'
            '0b747b991b7abe6a02dbb946d5d19dc504e5ecc916feba3f513dea2b23bbefe38f51227798a11cddca14f31afe01f4b17040c393f15ab2daaffcc6fc21382fe5')

prepare() {
  cd "dashboard-$pkgver"

  # Ship config
  cp "${srcdir}/local-config.json" .local-config.json
  cp "${srcdir}/local-config.json" config.json

  # Ensure the WASM binary is part of the static export (Next export copies /public)
  install -Dm0644 "${srcdir}/netbird.wasm" "public/netbird.wasm"
}

build() {
  cd "dashboard-$pkgver"
  npm install
  npm install --save-dev @types/chroma-js
  export NEXT_TELEMETRY_DISABLED=1
  export NODE_ENV=production

  npm run build -- --no-lint
}

package() {
  install -d "${pkgdir}/usr/share/webapps/${pkgname}/"
  cp -r "${srcdir}/dashboard-$pkgver/out/"* "${pkgdir}/usr/share/webapps/${pkgname}/"

  install -Dm0644 "${srcdir}/netbird.wasm" \
    "${pkgdir}/usr/share/webapps/${pkgname}/netbird.wasm"

  # License
  install -Dm0644 "${srcdir}/dashboard-$pkgver/LICENSE" \
    "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}

now it works. This is also needed in the local-config.json:

{
 ...
  "wasmPath": "/netbird.wasm"
 ...
}

You should add wasm mime in your reverse proxy (for example, nginx)

ssh feature not working, with error:

WebAssembly: Response has unsupported MIME type 'text/javascript' expected 'application/wasm'

netbird-dashboard is under AGPL-3.0 license