Arch Linux User Repository

@Meron35 Thanks for your feedback, fixed it.

@zxp19821005. The application icon is still incorrect in the updated build. This is due to upstream storing the icon in the incorrect path.

# original upstream and in current PKGBUILD
install -Dm644 "${srcdir}/usr/share/pixmaps/${_appname}.png" "${pkgdir}/usr/share/pixmaps/${pkgname%-bin}.png"
# correct path for icon
install -Dm644 "${srcdir}/usr/lib/${_appname}/resources/icons/${_appname}.png" "${pkgdir}/usr/share/pixmaps/${pkgname%-bin}.png"

@Meron35 Thanks for your feedback, fixed it.

There are some issues with the .desktop file which results in the application having the wrong icon, and it being unable to be pinned to dock properly. Both of these stem from the upstream .deb.

The .desktop file (in /data/usr/share/applications/noi.desktop) should be (note StartupWMClass)

[Desktop Entry]
Name=Noi
Comment=Noi
GenericName=Noi
Exec=noi-desktop %U
Terminal=false
Icon=noi-desktop
Type=Application
StartupNotify=true
Categories=GNOME;GTK;Utility
StartupWMClass=Noi

The PKGBUILD can be updated to the following to incorporate this (also note the fix for the default Electron icon)

# Maintainer: zxp19821005 <zxp19821005 at 163 dot com>
_appname=noi
pkgname="${_appname}-desktop-bin"
_pkgname=Noi
pkgver=0.4.0
_electronversion=29
pkgrel=4
pkgdesc="Power Your World with AI - Explore, Extend, Empower.(Prebuilt version)"
arch=('x86_64')
url="https://noi.nofwl.com/"
_ghurl="https://github.com/lencx/Noi"
license=('LicenseRef-custom')
provides=("${pkgname%-bin}=${pkgver}")
conflicts=("${pkgname%-bin}")
depends=(
    "electron${_electronversion}"
)
source=(
    "${pkgname%-bin}-${pkgver}.deb::${_ghurl}/releases/download/v${pkgver}/${_appname}_linux_amd64_${pkgver}.deb"
)
sha256sums=('80921cf6a68aac06ef1051dfd23573e040bedabf17f90717bafe7085ec0fd928')
prepare() {
    bsdtar -xf "${srcdir}/data."*
    # Create .desktop entry
    cat <<EOF > ${srcdir}/usr/share/applications/${_appname}.desktop
[Desktop Entry]
Name=Noi
Comment=Noi
GenericName=Noi
Exec=noi-desktop %U
Terminal=false
Icon=noi-desktop
Type=Application
StartupNotify=true
Categories=GNOME;GTK;Utility
StartupWMClass=Noi
EOF
}
package() {
    install -Dm755 -d "${pkgdir}/usr/"{bin,lib/"${pkgname%-bin}"}
    # Copy directory over
    cp -Pr --no-preserve=ownership "${srcdir}/usr/lib/${_appname}/"* "${pkgdir}/usr/lib/${pkgname%-bin}"
    ln -sf "/usr/lib/${pkgname%-bin}/${_appname}" "${pkgdir}/usr/bin/${pkgname%-bin}"
    install -Dm644 "${srcdir}/usr/share/applications/${_appname}.desktop" "${pkgdir}/usr/share/applications/${pkgname%-bin}.desktop"
    # Fix Icon
    install -Dm644 "${srcdir}/usr/lib/${_appname}/resources/icons/${_appname}.png" "${pkgdir}/usr/share/pixmaps/${pkgname%-bin}.png"
    install -Dm644 "${srcdir}/usr/lib/${_appname}/LICENSE"* -t "${pkgdir}/usr/share/licenses/${pkgname}"
}

@neitsab Thank you for your encouragement.

Thanks for packaging this! I had just stumbled upon it and wanted to give it a try, and was glad to find it neatly packaged in the AUR. It works well for me 😊 Cheers

@webcaptcha All right.Fixed it.

@zxp19821005 the shortcut is good for now, but still getting error I'm aborting now. You need to make sure that /usr/lib/noi-desktop/chrome-sandbox is owned by root and has mode 4755

@webcaptcha Thanks for your feedback, it's my fault,I havn't created the right shortcut to /usr/bin, fixed it.