Arch Linux User Repository

Hi, this package needs the following changes:

1. Change licenses() to the actual licenses of the project.
2. Remove rust from makedepends(). Just list cargo according to the Rust package guidelines
3. Use updpkgsums to set the checksums so that the desktop file is properly checked for.
4. Add a prepare() function to properly set up the build environment as described in the Rust package guidelines
5. In the build() function, export RUSTUP_TOOLCHAIN=stable and use --frozen --all-features as described in the Rust package guidelines
6. Properly list the depends(). Using namcap, you can actually figure out the dependencies of any package on Arch.
7. Remove armv7 as that's not a supported arch.

diff --git a/PKGBUILD b/PKGBUILD
index d715eb2..16528b0 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,17 +1,18 @@
 # Maintainer: Louis Dalibard <ontake@ontake.dev>
 pkgname=ntsc-rs-gui-git
-pkgver=0.7.3.r365.751279a
+pkgver=0.9.3.r670.bddab2d
 pkgrel=1
-pkgdesc='ntsc-rs is a video effect which emulates NTSC and VHS video artifacts.'
-arch=('x86_64' 'aarch64' 'armv7')
+pkgdesc="ntscrs is a video effect which emulates NTSC and VHS video artifacts."
+arch=('x86_64' 'aarch64')
 url=https://github.com/valadaptive/ntsc-rs
-license=('GPL3')
-depends=('gstreamer' 'gst-libav' 'gst-plugins-bad' 'gst-plugins-base' 'gst-plugins-good' 'gst-plugins-ugly')
-makedepends=('cargo' 'git' 'rust')
+license=('Apache-2.0 AND ISC AND MIT')
+depends=('gstreamer' 'gst-plugins-base-libs' 'glibc' 'glib2' 'hicolor-icon-theme' 'libgcc' 'openssl' 'libwebp')
+makedepends=('cargo' 'git')
 conflicts=("${pkgname%-git}")
 provides=("${pkgname%-git}")
 source=("git+$url.git" "ntsc-rs.desktop")
-sha256sums=('SKIP' 'SKIP')
+sha256sums=('SKIP'
+            '2382c3204625727781d42f3b9cc9ca85164048fec9ce208a7111ba14b25dfb89')

 pkgver() {
   cd ${pkgname%-gui-git}
@@ -19,11 +20,18 @@ pkgver() {
   printf %s.r%s.%s $(grep ^version Cargo.toml|cut -d\" -f2) $(git rev-list --count HEAD) $(git describe --always)
 }

+prepare() {
+  cd "$srcdir/${pkgname%-gui-git}"
+  export RUSTUP_TOOLCHAIN=stable
+  cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
+}
+
 build() {
   cd ${pkgname%-gui-git}
   cd crates/gui
   export CARGO_TARGET_DIR=target
-  cargo build --release 
+  export RUSTUP_TOOLCHAIN=stable
+  cargo build --frozen --release --all-features
 }

 package() {