Arch Linux User Repository

I built the package within a clean chroot environment like https://wiki.archlinux.org/title/DeveloperWiki:Building_in_a_clean_chroot and I use the package myself.

I don't have any problem, neither import PyNUTClient.PyNUT as PyNUT on NUT-Monitor-py3qt6. Are you on the latest version?

To make it work, I needed to change

import PyNUTClient.PyNUT as PyNUT to import PyNUT in NUT-Monitor-py3qt6. I don't know if that's ok or if anyone else had the same problem.

@fow0ryl thanks for the hint about Qt6. I was not aware about the Qt6 stuff in release 2.8.4.

Since there is a qt6 based nut-monitor I'm using qt6 only, and removed all qt5 dependencies. I have cloned and modified your PKGBUILD only a little bit. Works without problems. So why stay on qt5 ?

# Maintainer: Brody <archfan at brodix dot de>
# Contributor: D. Can Celasun <can[at]dcc[dot]im>
# Contributor: Dan Ziemba <zman0900@gmail.com>

_pkgname=nut
pkgname=nut-monitor
pkgver=2.8.4
pkgrel=1
pkgdesc='GUI to manage devices connected a NUT server'
arch=(any)
url=http://www.networkupstools.org/
_ghurl=https://github.com/networkupstools/${_pkgname}
license=(GPL-3.0-or-later)
depends=(
  hicolor-icon-theme
  nut
  python
  python-pyqt6
)
makedepends=(
  desktop-file-utils
  git
)
conflicts=(${pkgname})
source=(${_pkgname}::git+${_ghurl}.git#tag=v${pkgver})
sha256sums=('6276aa5ba1a2a7ad3831cac7db090a7bbe9bbbc98c5e8723d57e25f09240e254')

prepare() {
  cd ${_pkgname}

  ./autogen.sh

  sed \
    's|os.path.dirname( sys.argv\[0\] )|"/usr/share/nut-monitor"|' \
    -i scripts/python/app/NUT-Monitor-py3qt6.in
}

build() {
  # configuration adopted from the nut package
  local _configure_args
  _configure_args=(
    --prefix=/usr
    --datadir=/usr/share/nut
    --libexecdir=/usr/lib/nut
    --sbindir=/usr/bin
    --sysconfdir=/etc/nut
    --with-altpidpath=/run/nut
    --with-cgipath=/usr/share/nut/cgi
    --with-drvpath=/usr/lib/nut
    --with-htmlpath=/usr/share/nut/html
    --with-pidpath=/run/nut
    --with-statepath=/var/lib/nut
    --without-python2
  )

  cd ${_pkgname}

  ./configure \
    "${_configure_args[@]}"
}

package() {
  cd ${_pkgname}/scripts/python/app

  install -Dm755 -t "${pkgdir}"/usr/bin \
    NUT-Monitor-py3qt6

  install -Dm644 -t "${pkgdir}"/usr/share/appdata \
    nut-monitor.appdata.xml

  install -Dm644 -t "${pkgdir}"/usr/share/${pkgname}/pixmaps \
    pixmaps/*

  install -Dm644 -t "${pkgdir}"/usr/share/${pkgname}/ui \
    ui/*.ui

  install -Dm644 -t "${pkgdir}"/usr/share/${pkgname}/icons/256x256 \
    icons/256x256/nut-monitor.png

  local _res
  for _res in 48x48 64x64 256x256 scalable; do
    install -Dm644 -t "${pkgdir}"/usr/share/icons/hicolor/${_res}/apps \
      icons/${_res}/*
  done

  desktop-file-install \
    --dir="${pkgdir}"/usr/share/applications \
    nut-monitor-py3qt6.desktop

  ln -sr "${pkgdir}"/usr/bin/NUT-Monitor-py3qt6 \
    "${pkgdir}"/usr/bin/"${pkgname}"
}

@brody updated, thanks.

With version 2.8.3, there is no longer a dependency on python-telnetlib-313-and-up.

@fow0ryl upstream doesn't support qt6 and the app depends on qt5, just search for qt5 in the PKGBUILD.

@ToadKing thanks, should be fixed now.

There's a file conflict with the latest nut package:

error: failed to commit transaction (conflicting files)
nut-monitor: /usr/lib/python3.13/site-packages/PyNUT.py exists in filesystem (owned by nut)