Arch Linux User Repository

PKGBUILD for those who want to stick with an older version, or install multiple versions side by side.

pkgver=0.102.1
_mnrver=$(echo $pkgver | cut -d. -f2)
pkgname=nwjs$_mnrver-bin
pkgrel=1
pkgdesc="Runtime based on Chromium and node.js"
arch=(x86_64)
url="https://nwjs.io"
license=('MIT')
optdepends=(
  'nodejs: npm package support'
  'nw-gyp: native add-on build tool for node-webkit'
)
options=(!debug)
source=(
  nwjs-$pkgver.tar.gz::https://dl.nwjs.io/v$pkgver/nwjs-v$pkgver-linux-x64.tar.gz
)
sha256sums=('SKIP')

prepare() {
  # Simplify folder name (only if exists, in case of using '--noextract').
  if [ -d nwjs-v$pkgver-linux-x64 ]; then
    rm -rf nwjs && mv nwjs-v$pkgver-linux-x64 nwjs
  fi
}

package() {
  depends=(gtk3 nss libxss)
  provides=(nwjs node-webkit)

  install -Dm755 "$srcdir"/nwjs/{chrome_crashpad_handler,nw}         -t "$pkgdir"/opt/nwjs$_mnrver/
  install -Dm644 "$srcdir"/nwjs/{icudtl.dat,v8_context_snapshot.bin} -t "$pkgdir"/opt/nwjs$_mnrver/
  install -Dm644 "$srcdir"/nwjs/{nw_{100,200}_percent,resources}.pak -t "$pkgdir"/opt/nwjs$_mnrver/

  for d in lib locales; do
    for f in $(find "$srcdir"/nwjs/$d -type f -printf "%P\n"); do
      install -Dm644 "$srcdir"/nwjs/$d/$f -T "$pkgdir"/opt/nwjs$_mnrver/$d/$f
    done
  done

  mkdir -p "$pkgdir"/usr/bin/ && ln -sr "$pkgdir"/opt/nwjs$_mnrver/nw -T "$pkgdir"/usr/bin/nw$_mnrver
}

I was hoping to specified it as optdeps directly, but I applied it at a moment.

I think it would be more correct to add nwjs-ffmpeg-codecs to provides, and remove nwjs from optdepends.

nwjs-ffmpeg-codecs is no longer existing and renamed to chromium-ffmpeg for all Chromiums.

Ok, I'll remove it with the next version.

I added hooks to chromium-ffmpeg{,-bin} pkgs to replace it. So this pkg can remove ffmpeg from source.

@oech3, I can do that, but it won't work. Without removing libffmpeg.so from nwjs/lib/, it will be loaded as a higher priority one. Of course, I can put the original file in nwjs/lib_fb (to load it as a fallback). And the third-party one can be installed as a separate package in nwjs/lib/. It will work, but it doesn't look very good... Bad idea, don't want to make wrappers for all binaries that require libffmpeg.so.

Would you put #!/usr/bin/bash; LD_LIBRARY_PATH=/opt/nwjs exec /opt/nwjs/nw "$@" at /usr/bin/nw which avoids to override .so at here?

Added .desktop file with MimeType=inode/directory in version 0.102.1. Now, you can run NW.js applications (eg win versions of RPG Maker MV games) by opening the folder (containing package.json) via 'Open With...' menu.

Thankyou. I might try to improve external codec pkg after orphaned.

And this may needed to take same packaging layout with electronNM for RMMV as file API of nw is not stable.

Or use chromium -allow-file-access-from-files -window-size="816,624" -autoplay-policy=no-user-gesture-required -proxy-server=dummy -user-data-dir=savedata -app=file://pathto/index.html.