Arch Linux User Repository

v0.9.0.r332 brings proxy support, thank you @aarnt ! [2250904|e846990]

• PKGBUILD updated to match a closer version to the official one provided on github
• PKGBUILD WITH_KNOTIFICATION=1 -> Enable the Plasma/knotifications support notifier
• PKGBUILD WITH_DARK_ICON=0 -> Replace grey icon for dark theme support by the original green icon
• PKGBUILD -j removed, if you need parallel build, set MAKEFLAGS in /etc/makepkg.conf
• PKGBUILD qt5-tools added as makedeps (a new requirement to build octopi-sudo)
• I didn't feel it was necessary to keep the old numix icons but if you want them back just let me know

Updated

• requires the AUR package qt-sudo
• qt6 will be automatically downloaded
• no more sudo/ source folder
• parallel build (8 jobs)

Sorry for the delay, had it no more installed, feel free to msg mr.dovi [at] gmail.com when there is a blocker issue or you want to maintain it

Getting the following error when trying to install this package:

Info: creating stash file /home/user/.cache/paru/clone/octopi-git/src/octopi/.qmake.stash
Project ERROR: Unknown module(s) in QT: core5compat

remove the 'sudo' from #63 and #98 solve the issue

real fix:

# Maintainer           : Arnaud Dovi <mr.dovi@gmail.com>
# Contributor          : SharkEzz <icraft640@gmail.com>
# Contributor          : Nikola Milinković <nikmil@gmail.com>

# WITH_KNOTIFICATION = 0 -> Default notifier is use simply qt5
# WITH_KNOTIFICATION = 1 -> Enable the Plasma/knotifications support notifier
WITH_KNOTIFICATION=0

# WITH_DARK_ICON = 0 -> Default icons
# WITH_DARK_ICON = 1 -> Replace the green icon by a dark one (dark themes support)
WITH_DARK_ICON=1

pkgname=octopi-git
pkgver=0.15.0.r15.69e85ddd
pkgrel=1
pkgdesc="This is Octopi, a powerful Pacman frontend using Qt libs"
arch=('x86_64')
url="https://github.com/aarnt/octopi"
license=('GPL2')
depends=(
  'gcc-libs' # libgcc_s.so libstdc++.so
  'glibc' # libc.so
  'alpm_octopi_utils-git'
  'qt5-base' # libQt5Core.so libQt5Gui.so libQt5Network.so libQt5Widgets.so libQt5Xml.so
  'pkgfile'
  'qtermwidget' # libqtermwidget5.so
  'qt-sudo'
  'pacman' # libalpm.so
)
makedepends=(
  'git'
  'qt5-base'
  'qt5-tools'
)
provides=(
  'octopi'
  'octopi-cachecleaner'
  'octopi-helper'
  'octopi-notifier'
  'octopi-repoeditor'
)
conflicts=(
  'octopi'
  'octopi-cachecleaner'
  'octopi-helper'
  'octopi-notifier'
  'octopi-repoeditor'
  'octopi-dev'
  'octopi-kde-git'
  'octopi-notifier-frameworks'
  'octopi-notifier-qt5'
  'octopi-notifier-noknotify'
)
#install=octopi.install
source=(
  'git+https://github.com/aarnt/octopi.git'
  'octopi_dark.png'
)
sha256sums=(
  'SKIP'
  '49aa640be835eb9ccf216f44a2d86aba3b39bf349e62b855192096526883cdc0'
)

pkgver() {
  cd octopi
  printf "%s" "$(git describe --long --tags | sed 's/^v//;s/\([^-]*-\)g/r\1/;s/-/./g')"
}

prepare() {
  cd octopi

  sed 's|/usr/local/bin|/usr/bin|g' -i src/constants.h

  [[ "$WITH_KNOTIFICATION" == "1" ]] && sed -e "s|DEFINES += ALPM_BACKEND #KSTATUS|DEFINES += ALPM_BACKEND KSTATUS|" -i notifier/octopi-notifier.pro
  if [[ "$WITH_DARK_ICON" -eq "1" ]]; then
    cp resources/images/octopi_green.png resources/images/octopi_green.bak.png
    cp "${srcdir}/octopi_dark.png" resources/images/octopi_green.png
  fi
  cp resources/images/octopi_green.png resources/images/octopi.png
  # https://github.com/aarnt/octopi/commit/2250904a902fca96ea16adf463400fbda913aa70
  #patch --forward --strip=2 --input="${srcdir}/2250904a902fca96ea16adf463400fbda913aa70.patch"
}

build() {
  cd octopi
  echo "Starting build..."
  qmake-qt5 PREFIX=/usr QMAKE_CFLAGS="${CFLAGS}" QMAKE_CXXFLAGS="${CXXFLAGS}" QMAKE_LFLAGS="${LDFLAGS}" octopi.pro
  make

  _subdirs="cachecleaner helper notifier repoeditor"

  for _subdir in $_subdirs; do
    pushd $_subdir
    echo "Building octopi-$_subdir..."
    qmake-qt5 PREFIX=/usr QMAKE_CFLAGS="${CFLAGS}" QMAKE_CXXFLAGS="${CXXFLAGS}" QMAKE_LFLAGS="${LDFLAGS}" "octopi-$_subdir.pro"
    make
    popd
  done
}

package() {
  cd octopi
  make INSTALL_ROOT="${pkgdir}" install

  _subdirs="cachecleaner helper notifier repoeditor"

  for _subdir in $_subdirs; do
    pushd $_subdir
    make INSTALL_ROOT="${pkgdir}" install
    popd
  done
}

/tmp/yay/octopi-git/PKGBUILD: línea 86: pushd: sudo: No existe el fichero o el directorio

v0.9.0.r332 brings proxy support, thank you @aarnt ! [2250904|e846990]

• PKGBUILD updated to match a closer version to the official one provided on github
• PKGBUILD WITH_KNOTIFICATION=1 -> Enable the Plasma/knotifications support notifier
• PKGBUILD WITH_DARK_ICON=0 -> Replace grey icon for dark theme support by the original green icon
• PKGBUILD -j removed, if you need parallel build, set MAKEFLAGS in /etc/makepkg.conf
• PKGBUILD qt5-tools added as makedeps (a new requirement to build octopi-sudo)
• I didn't feel it was necessary to keep the old numix icons but if you want them back just let me know