Package Details: opencollada 1:1.6.68-3

Git Clone URL: https://aur.archlinux.org/opencollada.git (read-only, click to copy)
Package Base: opencollada
Description: Stream based reader and writer library for COLLADA files
Upstream URL: https://github.com/KhronosGroup/OpenCOLLADA
Licenses: GPL
Submitter: bartus
Maintainer: bartus
Last Packager: bartus
Votes: 5
Popularity: 0.35
First Submitted: 2024-11-13 21:10 (UTC)
Last Updated: 2024-11-13 21:52 (UTC)

Latest Comments

fsyy commented on 2025-11-18 14:37 (UTC) (edited on 2025-11-18 14:41 (UTC) by fsyy)

"git clone" one of the above Git Clone URLs

use your favourite editor to edit the PKGBUILD file.

either add the options in the PKGBUILD file or use the one i paste below.

run "makepkg -si"

and it should work.

PKGBUILD:

# Maintainer: bartus <arch-user-repoᘓbartus.33mail.com>

pkgname=opencollada
pkgver=1.6.68
pkgrel=3
epoch=1
pkgdesc="Stream based reader and writer library for COLLADA files"
arch=(x86_64)
url="https://github.com/KhronosGroup/OpenCOLLADA"
license=('GPL')
depends=('libxml2' 'pcre')
makedepends=('git' 'cmake')
source=('opencollada.conf'
        'pcre.patch'
        'gcc.patch'
        "git+https://github.com/KhronosGroup/OpenCOLLADA.git#tag=v${pkgver}")
sha256sums=('2fc9656a2b881ca4528416daa91fc525adaa97d73e96a18b41aa7856270eba1f'
            'f37a7cbadcaa06b70133f76c509c61bdcf13715bc13aed11b5db83ef594813b3'
            'ea2b2de957055e9d9fc2cad31f7f82810816e2f935db8f72fe5538642574926a'
            'b201b99935d817b18bd1588cce824d6e891102d1d8dbe272cbd9a4ce91ec4f8e')

prepare() {
  cd OpenCOLLADA

  patch -Np1 -i "$srcdir"/pcre.patch
  patch -Np1 -i "$srcdir"/gcc.patch
}

build() {
  cd OpenCOLLADA

  [[ -d build ]] && rm -r build
  mkdir build && cd build

  cmake .. \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DUSE_SHARED=ON \
    -DUSE_STATIC=OFF \
    -DCMAKE_POLICY_VERSION_MINIMUM=3.5
  make
}

package() {
  cd OpenCOLLADA/build

  make DESTDIR="$pkgdir" install

  install -Dm644 "$srcdir"/opencollada.conf "$pkgdir"/etc/ld.so.conf.d/opencollada.conf
}

# vim:set ts=2 sw=2 et:

morsmortium commented on 2025-05-12 15:16 (UTC)

Hi! Could you add -DCMAKE_POLICY_VERSION_MINIMUM=3.5 to the cmake command? The original repository did not get commits in 7 years, and even the fork packaged in opencollada-blender-git needs it, so it is unlikely this will ever get updated by the developer

patlefort commented on 2025-05-02 11:38 (UTC)

This package is affected by the cmake < 3.5 compatibility issue:

CMake Error at CMakeLists.txt:21 (cmake_minimum_required):
  Compatibility with CMake < 3.5 has been removed from CMake.

Jenrikku commented on 2025-04-25 11:46 (UTC)

For Blender, a package called opencollada-blender-git that follows the fork mentioned by @cb88 exists.

cb88 commented on 2025-04-03 19:45 (UTC)

Also blender has been building against this version as of recently. It apparently includes some performance fixes and removes PCRE dep https://github.com/aras-p/OpenCOLLADA

cb88 commented on 2025-04-03 18:17 (UTC)

Fails to build with cmake 4.0