Package Details: openra-rv-git 3959.git.66c9a08-1

Git Clone URL: https://aur.archlinux.org/openra-rv-git.git (read-only, click to copy)
Package Base: openra-rv-git
Description: A Command & Conquer: Red Alert 2-inspired mod of OpenRA
Upstream URL: https://github.com/MustaphaTR/Romanovs-Vengeance
Licenses: GPL3
Provides: openra-rv
Submitter: fusion809
Maintainer: fusion809
Last Packager: fusion809
Votes: 1
Popularity: 0.005529
First Submitted: 2019-03-23 11:54 (UTC)
Last Updated: 2023-01-10 11:30 (UTC)

Dependencies (18)

Required by (0)

Sources (4)

Latest Comments

DLAN commented on 2022-07-17 02:19 (UTC) (edited on 2022-07-17 09:33 (UTC) by DLAN)

I was able to get the game working without any upstream changes. The reason for the ./engine/packaging/functions.sh error is because the PKGBUILD is attempting to call make version VERSION=${pkgver}" before the engine is downloaded. The engine downloads during the standard make call, or it can be manually downloaded beforehand.

Here is an overhauled PKGBUILD that I successfully built and run with:

# Maintainer: Brenton Horne <brentonhorne77 at gmail dot com>

pkgname=openra-rv-git
_pkgname=openra-rv
pkgver=3822.git.08da500
pkgrel=1
pkgdesc="A Command & Conquer: Red Alert 2-inspired mod of OpenRA"
arch=('any')
url="https://github.com/MustaphaTR/Romanovs-Vengeance"
license=('GPL3')
install=openra-rv.install
depends=('hicolor-icon-theme' 'gtk-update-icon-cache' 'zlib') # 'ttf-dejavu' 'openal' 'libgl' 'freetype2' 'sdl2' 
         # 'desktop-file-utils' 'xdg-utils' 'zenity'
makedepends=('dos2unix' 'git' 'unzip' 'dotnet-sdk')
provides=('openra-rv')
options=(!strip)
source=("git+${url}.git"
"openra-rv"
"openra-rv.appdata.xml"
"openra-rv.desktop")
md5sums=('SKIP'
         '80198a3797c5f4103536702d15e37f19'
         'cdade4bc4fcba3ea1d3dea6bd0e9a2c9'
         '98c237db6df1eb777658842765948ea2')

pkgver() {
    cd $srcdir/Romanovs-Vengeance
    no=$(git rev-list --count HEAD)
    hash=$(git log | head -n 1 | cut -d ' ' -f 2 | head -c 7)
    printf "${no}.git.${hash}"
}

prepare() {
    cd $srcdir/Romanovs-Vengeance
    dos2unix *.md
    printf "Success in converting docs...\n"
    ./fetch-engine.sh
    printf "Successfully fetched engine...\n"
}

build() {
    unset SOURCE_DATE_EPOCH
    $srcdir/Romanovs-Vengeance/packaging/linux/buildpackage.sh "${pkgver}"
}

package() {
    mkdir -p $pkgdir/usr/{bin,share/pixmaps,share/doc/packages/openra-rv,share/applications,share/appdata}

    install -Dm755 $srcdir/*.AppImage $pkgdir/usr/bin/openra-rv
    install -Dm644 $srcdir/openra-rv.desktop $pkgdir/usr/share/applications/openra-rv.desktop
    install -Dm644 $srcdir/openra-rv.appdata.xml $pkgdir/usr/share/appdata/openra-rv.appdata.xml

    cd $srcdir/Romanovs-Vengeance
    install -Dm644 README.md $pkgdir/usr/share/doc/packages/openra-rv/README.md
    mkdir -p $pkgdir/usr/share/icons/hicolor/{16x16,32x32,48x48,64x64,128x128,256x256,512x512}/apps
    for size in 16 32 48 64 128 256 512; do
      size="${size}x${size}"
      install -Dm644 packaging/artwork/icon_${size}.png $pkgdir/usr/share/icons/hicolor/${size}/apps/${_pkgname}.png
    done
    install -Dm644 packaging/artwork/icon_512x512.png ${pkgdir}/usr/share/pixmaps/${_pkgname}.png
}

I removed some of the dependencies that namcap indicated were unused, but I left them commented out because I don't know their original intention.

I dropped mono and added dotnet as a dependency. If mono is preferred, it will be far easier to build by hand.

I dropped the generic make script in favor of the buildpackage.sh script they supply. This also cleaned up a lot of the package() function, since it creates an AppImage.

I added the fetch-engine.sh script call to prepare() to fix the initial error reported below.

SOURCE_DATE_EPOCH needs to be unset because it conflicts with the AppImage squashfs processing. That can be removed once the upstream package is corrected.

I fixed the missing icons by using the correct _pkgname variable for the .png files.

fusion809 commented on 2021-02-11 10:30 (UTC)

@ullebe1 That's an upstream bug; I don't have any control over whether that file exists.

ullebe1 commented on 2021-02-11 10:28 (UTC) (edited on 2021-02-11 10:29 (UTC) by ullebe1)

Doesn't seem to build for me anymore. I've tried it in both a clean chroot with aurtils and just locally and get:

==> Starting build()...
sh: line 1: ./engine/packaging/functions.sh: No such file or directory
make: *** [Makefile:143: version] Error 1
==> ERROR: A failure occurred in build().
    Aborting...

for both.

ullebe1 commented on 2019-07-20 20:58 (UTC)

Seems like there is a missing dependency: "msbuild". On my system I can't build this package without it.

fusion809 commented on 2019-03-25 19:49 (UTC)

Doesn't build as of 26 Mar 2019, due to an upstream issue. Please do not report upstream issues here, go to https://github.com/MustaphaTR/Romanovs-Vengeance/issues/new. Usually if it is a build error they'll already know, as they have a Travis CI instance set up to check for Linux build errors.