Arch Linux User Repository

Hi! I have changed the PKGBUILD based on the output of the NAMCAP:

# Maintainer: Yurakaii <danndem@gmail.com>

_pname=OpenSCQ30
_powner=Oppzippy
_pkgid=com.oppzippy.$_pname

pkgbase=openscq30-bin
pkgname=("openscq30"-{cli,gui}-"bin")
pkgver=2.8.2
pkgrel=1
pkgdesc="Cross platform application for controlling settings of Soundcore headphones"
arch=(x86_64)
url="https://github.com/$_powner/$_pname"
license=('GPL-3.0-or-later')
options=('!debug')
source=(
    "$_pname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz"
    "${pkgbase}-cli-${pkgver}::$url/releases/download/v$pkgver/openscq30-cli-linux-${arch}"
    "${pkgbase}-gui-${pkgver}::$url/releases/download/v$pkgver/openscq30-gui-linux-${arch}")
sha256sums=('bae3650646edb1ba622122e4f62eff1a9f2ddfaa83e23ef882cffd1c8020328e'
            '7055786c365d5926aca1cba3f4414db7a7e11376e7f76517dbf139338e218d49'
            '011d16cbc82d86fdd698b839ed54b146ea6267d6055b7a4fbfd1dba80da23722')

package_openscq30-cli-bin() {
    # Metadata
    pkgdesc="$pkgdesc - CLI application"
    provides=('openscq30-cli')
    conflicts=('openscq30-cli')
    depends=('glibc' 'libgcc' 'dbus')
    ## Install binary
    install -Dm0755 "${pkgbase}-cli-${pkgver}" "$pkgdir/usr/bin/openscq30"
    # Packaging
    cd "$srcdir/$_pname-$pkgver"
    ## Install resources
    install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname" "LICENSE.txt"
    # shellcheck disable=SC2128
    ln -s "openscq30" "$pkgdir/usr/bin/openscq30-cli"
}

package_openscq30-gui-bin() {
    # Metadata
    pkgdesc="$pkgdesc - Cosmic GUI application"
    provides=('openscq30-gui')
    conflicts=('openscq30-gui')
    depends=('glibc' 'libgcc' 'dbus' 'hicolor-icon-theme' 'cosmic-icon-theme')
    ## Install binary
    install -Dm0755 "${pkgbase}-gui-${pkgver}" "$pkgdir/usr/bin/openscq30-gui"
    # Packaging
    cd "$srcdir/$_pname-$pkgver"
    ## Install resources
    install -Dm0644 -t "$pkgdir/usr/share/metainfo/" "gui/resources/$_pkgid.metainfo.xml"
    install -Dm0644 -t "$pkgdir/usr/share/icons/hicolor/scalable/apps/" "gui/resources/$_pkgid.svg"
    install -Dm0644 -t "$pkgdir/usr/share/applications/" "gui/resources/$_pkgid.desktop"
    install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname" "LICENSE.txt"
}

Works really well with Soundcore Space One. Thank you.