Arch Linux User Repository

Thanks for packaging this up, but this PKGBUILD doesn't result in a usable GUI for the 2021 version - and in fact it doesn't even build the GUI. Here is my updated PKGBUILD that got things working for me:

[Edit: Updated PKGBUILD to include the formdata files, which are necessary to actually fill the PDF forms]

# Maintainer: endlesseden
year=2021
_pkgname=opentaxsolver-$year
pkgname=$_pkgname-svn
pkgver=2021.r106
pkgrel=1
pkgdesc="An easy-to-use text-based calculator for US Tax Forms"
arch=('i686' 'x86_64' 'armv7h' 'aarch64')
url="http://opentaxsolver.sourceforge.net/"
license=('GPL2')
groups=(OTS)
depends=('gtk4')
makedepends=('subversion')
checkdepends=()
optdepends=()
provides=("$_pkgname")
conflicts=("$_pkgname")
source=("$_pkgname::svn://svn.code.sf.net/p/opentaxsolver/SrcCodeRepo/trunk/OTS_$year")
md5sums=('SKIP')

pkgver() {
  cd "$srcdir/$_pkgname"
  local ver="$(svnversion)"
  printf "$year.r%s" "${ver//[[:alpha:]]}"
}

prepare() {
    cd "$srcdir/$_pkgname"
    if [ ! -e "ots-$year" ];then 
        printf "#!/bin/bash \ncd /var/lib/${_pkgname} \n./Run_taxsolve_GUI" > ots-$year
        chmod +x ots-$year
    fi
}


build() {
    cd "$srcdir/$_pkgname"/src
    make
    cd Gui_gtk
    make
}

package() {
    cd "$srcdir/$_pkgname"

    install -D ots-$year -t "${pkgdir}/usr/bin/"
    install -D Run_taxsolve_GUI -t "${pkgdir}/var/lib/${_pkgname}/"

    cp -r bin "${pkgdir}/var/lib/${_pkgname}/"
    cp -r tax_form_files "${pkgdir}/var/lib/${_pkgname}/"
    mkdir -p "${pkgdir}/var/lib/${_pkgname}/src"
    cp -r src/formdata "${pkgdir}/var/lib/${_pkgname}/src"
}