Package Details: overwitch 2.1-2

Git Clone URL: https://aur.archlinux.org/overwitch.git (read-only, click to copy)
Package Base: overwitch
Description: JACK client for Overbridge devices
Upstream URL: https://github.com/dagargo/overwitch
Licenses: GPL-3.0-only
Submitter: tgirod
Maintainer: tgirod
Last Packager: tgirod
Votes: 2
Popularity: 0.001786
First Submitted: 2022-12-02 20:14 (UTC)
Last Updated: 2025-09-03 11:51 (UTC)

Latest Comments

SpotlightKid commented on 2025-09-01 16:46 (UTC)

This does not compile without error. See https://github.com/dagargo/overwitch/issues/85

Here's a fixed and improved PKGBUILD:

# Maintainer: Thomas Girod <tgirod@altu.fr>
# Contributor: Chris Arndt <aur -at- chrisarndt -dot- de>

pkgname=overwitch
pkgver=2.0
pkgrel=2
pkgdesc='JACK client for Overbridge devices'
arch=(x86_64)
url='https://github.com/dagargo/overwitch'
license=(GPL-3.0-only)
depends=(gettext gtk4 jack json-glib libsamplerate libsndfile libusb)
checkdepends=(cunit)
source=("https://github.com/dagargo/overwitch/releases/download/$pkgver/overwitch-$pkgver.tar.gz"
        'overwitch-fix-function-decl.patch::https://github.com/dagargo/overwitch/commit/9323053af0d4386a58bd12438aa4247ed56f75c9.patch')
sha256sums=('eaf3946ece677f8fe1ac5c12e2a66497ecd8982309f49aa01956f561eb8b1196'
            'd296605a22623ffd7a8b045be0cdab323eac7b20028fec34baa68216c0db23c2')

prepare() {
  cd $pkgname-$pkgver
  patch -p1 -N -r - -i "$srcdir"/overwitch-fix-function-decl.patch
}

build() {
  cd $pkgname-$pkgver
  autoreconf --install
  ./configure --prefix=/usr
  make
}

check() {
  cd $pkgname-$pkgver
  make check
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir/" install
  install -vDm 644 udev/*.rules -t "$pkgdir"/usr/lib/udev/rules.d
  install -vDm 644 udev/*.hwdb -t "$pkgdir"/usr/lib/udev/hwdb.d/
}