Arch Linux User Repository

I don't know if pushing to GIT is still not working (there are many updates pushed to AUR today?) but here is at least an updated PKGBUILD:

# Maintainer: Donald Webster <fryfrog@gmail.com>
# Maintainer: Shaun Bartlett <tixetsal@gmail.com>
# Contributor: Mikael Eriksson <mikael_eriksson@miffe.org>
# Contributor: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Rob Sletten <rsletten@gmail.com>
# Contributor: Tom Moore <t.moore01@gmail.com>
# Contributor: monty <linksoft@gmx.de>
# Contributor: Jon Wiersma <archaur@jonw.org>
# Contributor: Arthur <arthur.darcet@m4x.org>
# Contributor: Praekon <praekon@googlemail.com>

# Based on the plex-media-server package by Maxime Gauduin.

pkgname=plex-media-server-plexpass
pkgver=1.43.3.10861
_pkgsum=07dfddaeb
pkgrel=1
pkgdesc='The back-end media server component of Plex.'
arch=('x86_64' 'i686' 'armv7h' 'aarch64')
url='https://plex.tv/'
license=('custom')
options=('!emptydirs' '!strip' 'staticlibs')
provides=('plex-media-server')
conflicts=('plex-media-server')
backup=('etc/conf.d/plexmediaserver')
install='plex-media-server.install'
source=('plexmediaserver.conf.d'
        'plexmediaserver.service'
        'plexmediaserver.hook'
        'plex.sysusers'
        'plex.tmpfiles'
        'terms.txt')

source_aarch64=("https://downloads.plex.tv/plex-media-server-new/${pkgver}-${_pkgsum}/debian/plexmediaserver_${pkgver}-${_pkgsum}_arm64.deb")
source_armv7h=("https://downloads.plex.tv/plex-media-server-new/${pkgver}-${_pkgsum}/debian/plexmediaserver_${pkgver}-${_pkgsum}_armhf.deb")
source_x86_64=("https://downloads.plex.tv/plex-media-server-new/${pkgver}-${_pkgsum}/redhat/plexmediaserver-${pkgver}-${_pkgsum}.x86_64.rpm")
source_i686=("https://downloads.plex.tv/plex-media-server-new/${pkgver}-${_pkgsum}/redhat/plexmediaserver-${pkgver}-${_pkgsum}.i686.rpm")

sha256sums=('b7f2fb1cbedde54a79a1794ec9f35f8bdeb033a4c5453ec77944ca7fe77cd9b7'
            '525b4b3b7db69c4abf696116c9f41d7a3cb3b572186200d0720bb96ec155fbd4'
            'a94c798e3a1b5614020e3dd6ec80d378c0401fa08f411769527ad87a6898e80c'
            'c597bee0bcbb59ed791651555a904e5f7e9d2e82f6c6986b6352e5fc38e5b557'
            'b7ff6525a3c7a8be885edc85bb523095f8e25ddb38873127e2a4e97b28f2c7ad'
            '7bb97271eb2dc5d1dcb95f9763f505970d234df17f1b8d79b467b9020257915a')
sha256sums_x86_64=('2c1ff73ffd2ab8c8523fb5d37394c3cccffe0e8bd662b8a78749a7385874fb6b')
sha256sums_i686=('2d22d0061aefa7c9662fb86f6fcc19f02e6e2478f5b0fadc2dad24c4bd9d371c')
sha256sums_armv7h=('f22851c1611d03df736fd0cd9af0bc15f53c8767fd1ff69a85febbaeb22feab9')
sha256sums_aarch64=('2d4006110e55cd3920c82d8aec83db21b943d57430a94db486ffbd01902f15ae')

prepare() {
  if [[ $CARCH = armv7h ]] || [[ $CARCH = aarch64 ]]; then
    bsdtar -xf data.tar.xz
  fi
}

package() {
  install -d -m 755 "${pkgdir}/usr/lib/plexmediaserver"
  cp -dr --no-preserve='ownership' "${srcdir}/usr/lib/plexmediaserver" "${pkgdir}/usr/lib/"

  install -D -m 644 "${srcdir}/plexmediaserver.conf.d" "${pkgdir}/etc/conf.d/plexmediaserver"
  install -D -m 644 "${srcdir}/plexmediaserver.service" "${pkgdir}/usr/lib/systemd/system/plexmediaserver.service"
  install -D -m 644 "${srcdir}/plex.sysusers" "${pkgdir}/usr/lib/sysusers.d/plex.conf"
  install -D -m 644 "${srcdir}/plex.tmpfiles" "${pkgdir}/usr/lib/tmpfiles.d/plex.conf"

  install -D -m 644 "${srcdir}/terms.txt" "${pkgdir}/usr/share/licenses/${pkgname}/terms.txt"
  install -D -m 644 "${srcdir}/plexmediaserver.hook" "${pkgdir}/usr/share/doc/${pkgname}/plexmediaserver.hook"
}

# vim: ts=2 sw=2 et:

'Sadly, due to a number of packages getting malware they've disabled pushes to the AUR. :('

Aww man, that's a pain in the butt!, OK thanks for letting me know i shall let my users know.

fryfrog@apollo …/plex-media-server-plexpass  on  master [?⇡] ❯ git push
The AUR is down due to maintenance. We will be back soon.
fatal: Could not read from remote repository.

Please make sure you have the correct access rights
and the repository exists.

Sadly, due to a number of packages getting malware they've disabled pushes to the AUR. :(

Hi fryfrog, any chance of a bump in the package version please, this is out of date:-

pkgver=1.43.3.10828

Is anyone actually having issues? The downloads still seem to be available at the expected urls. If they change, we'll just change the package to use the new urls.

Yep, I got the Plex alert message and bopped over here to see what's what. If this is implemented in the package / upgrade, then I'll just wait. If this is something that has to be done locally...welp, I've got the curl script. :-D

Plex alert: Dear Plex User,

You are receiving this email because our records show you are running Plex Media Server on a Linux distribution that uses Redhat or Debian based package managers, this includes Ubuntu, Raspbian, Linux Mint, and other popular distros. If you’re running Plex Media Server in Docker or NAS Devices you can ignore this email.

We have recently made changes to our build systems that will require you to update how your Plex Media Server is configured in order to continue receiving versions updates via your package manager....it continues, but that's the gist.

Something like: https://repo.plex.tv/deb/pool/main/p/plexmediaserver/plexmediaserver_1.43.0.10492-121068a07_amd64.deb https://repo.plex.tv/deb/pool/main/p/plexmediaserver/plexmediaserver_1.43.0.10492-121068a07_arm64.deb

Packages URL: https://repo.plex.tv/deb/dists/public/main/binary-amd64/Packages.gz

Not sure if this affects us, https://support.plex.tv/articles/235974187-enable-repository-updating-for-supported-linux-server-distributions/ looks like they've changed where they are releasing plex to.

@m0x: Check the date you received the email from Plex, and compare it with the date you upgraded to the patched version (look in the pacman log). My guess is you upgraded before you saw the email.

@ectospasm fixed. It was my understanding 1.42.2 was needed; 1.42.1 was what I was running when Plex sent me the email notification.