Arch Linux User Repository

Hello. I suggest the following changes:

# Maintainer: HRKings <hrkings@***.com>
_pkgname=pokemonsay-newgenerations
pkgname=${_pkgname}-git
pkgver=2.0.0.r0.gf8a24a0
pkgrel=1
pkgdesc='Like cowsay but for pokemon only'
arch=(any)
url='https://github.com/HRKings/pokemonsay-newgenerations'
license=('MIT')
depends=(cowsay)
makedepends=(git)
provides=(pokemonsay $_pkgname)
conflicts=($_pkgname)
source=("${_pkgname}::git+${url}")
md5sums=('SKIP')

pkgver() {
    cd ${_pkgname}
    printf -- '%s.r%s.g%s' \
        "$(git describe --tags --abbrev=0 | sed 's/^v//')" \
        "$(git rev-list --count "$(git describe --tags --abbrev=0)"...HEAD)" \
        "$(git rev-parse --short=7 HEAD)"
}

prepare() {
    cd ${_pkgname}

    # Run grep first to make sure match is found in files

    echo 'Changing installation path in pokemonsay.sh...'
    grep -q '^INSTALL_PATH=.*$' pokemonsay.sh
    sed 's#^INSTALL_PATH=.*$#INSTALL_PATH=/usr/share/'"${_pkgname}"'#' -i pokemonsay.sh

    echo 'Changing command in pokemonthink.sh...'
    grep -q '^./pokemonsay.sh --think .*$' pokemonthink.sh
    sed 's#^./pokemonsay.sh --think .*$#pokemonsay --think "$@"#' -i pokemonthink.sh
}

package() {
    cd ${_pkgname}
    # Install pokemon cowfiles
    install -Dm644 -t "${pkgdir}/usr/share/${_pkgname}/pokemons" pokemons/*

    # Install the README and LICENSE
    install -Dm644 -t "${pkgdir}/usr/share/doc/${_pkgname}" README.md
    install -Dm644 -t "${pkgdir}/usr/share/doc/${_pkgname}/res" res/example.png
    install -Dm644 -t "${pkgdir}/usr/share/licenses/${_pkgname}" LICENSE

    # Install the scripts
    install -Dm755 pokemonsay.sh "${pkgdir}"/usr/bin/pokemonsay
    install -Dm755 pokemonthink.sh "${pkgdir}"/usr/bin/pokemonthink
}