Arch Linux User Repository

@ccorn:

1. I prefer tabs
2. Unnecessary
3. ...
4. It IS complete, actually. External (of those listed in depends array) and base-devel dependencies are not included.
5. Both system and AUR version works fine for me. Did you mean 0.4.5?
6. Unnecessary
7. Fixed (I wasted my time fixing something nobody's going to use anyway :( )
8. Done
9. I don't think this is necessary
10. License is in /usr/share/licenses/common/GPL2/license.txt and conforms to https://wiki.archlinux.org/title/PKGBUILD#license

I have accumulated some changes to the PKGBUILD. Most of those I had previously applied to AUR's former ponscripter-sekaiproject at least locally.

Summary of the changes:

• Use 2 spaces instead of tabs for indenting (and according modeline)
• Define and use helper variables _pkgname and _repo
• Oh, you do autodetection of release version. Nice! Keeping that.
• Complete depends and makedepends
• Use internal smpeg2 because I had trouble with the system version
• More configure arguments to control installation prefix and library usage
• Fix manpages
• Use make install
• Create symbolic link ponscripter to ponscr
• Install license

The result gets built correctly in a chroot and works fine with both the former narcissu2-en and the recent narcissu2.

Here is my modified PKGBUILD, listed directly because that is shorter than the diff:

# Maintainer: D. Can Celasun <can[at]dcc[dot]im>

pkgname=ponscripter
_pkgname=ponscripter-fork
_repo=07th-mod/$_pkgname
pkgver=v3.0.1
_pkgver=$(curl -s "https://api.github.com/repos/$_repo/releases/latest" | \
          grep tag_name | cut -d\" -f4)
pkgrel=1
pkgdesc="Fork of the Ponscripter visual novel engine to take advantage of SDL2 and improve Steam integration"
arch=(i686 x86_64 aarch64)
url=https://github.com/$_repo
license=(GPL)
# Needs internal smpeg2
depends=(bzip2 freetype2 libjpeg-turbo libogg libpng libvorbis sdl2 sdl2_image sdl2_mixer zlib)
makedepends=(curl docbook-xsl docbook5-xml git perl xmlto)
source=(git+https://github.com/07th-mod/ponscripter-fork.git#tag=$_pkgver)
sha256sums=('SKIP')

pkgver() {
  echo $_pkgver
}

build() {
  cd "${srcdir}/${_pkgname}"
  ./configure --prefix=/usr --no-werror \
    --disable-internal-libs \
    --disable-internal-sdl \
    --disable-internal-sdlimage \
    --with-external-sdl-mixer \
    --disable-internal-bz \
    --enable-internal-smpeg
  make
  # Fix manpages
  sed -i 's/^  *\././' doc/*.[1-8]
}

package() {
  cd "${srcdir}/${_pkgname}"
  install -dm755 "${pkgdir}/usr/share/man/"man{6,7}
  # No DESTDIR support, need to bend PREFIX
  make install PREFIX="${pkgdir}/usr"
  ln -s ponscr "${pkgdir}/usr/bin/ponscripter"
  install -Dm644 -t "${pkgdir}/usr/share/doc/${pkgname}" \
    BUGS CHANGES COPYING MANUAL README.md TODO
  install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}

# vim:set ts=2 sw=2 et: